B4X

Decrypt File in Chunks using 256-bit AES

See more Encryption Examples

Shows how to decrypt a file chunk-by-chunk using FirstChunk/LastChunk properties and accumulate the results in memory with a Chilkat BinData object. B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  This example decrypts the file previously encrypted in this example:
'  Encrypt File in Chunks using AES CBC

Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 256

crypt.SetEncodedKey("000102030405060708090A0B0C0D0E0F000102030405060708090A0B0C0D0E0F", "hex")
crypt.SetEncodedIV("000102030405060708090A0B0C0D0E0F", "hex")

Dim fileToDecrypt As String = "c:/temp/qa_output/hamlet.enc"
Dim facIn As ChilkatFileAccess
facIn.Initialize
success = facIn.OpenForRead(fileToDecrypt)
If success <> True Then
    Log("Failed to open file to be decrytped.")
    Return
End If


'  Let's decrypt in 32000 byte chunks.
Dim chunkSize As Int = 32000
Dim numChunks As Int = facIn.GetNumBlocks(chunkSize)

crypt.FirstChunk = True
crypt.LastChunk = False

Dim bd As ChilkatBinData
bd.Initialize
Dim bdDecrypted As ChilkatBinData
bdDecrypted.Initialize

Dim i As Int = 0
Do While i < numChunks
    i = i + 1
    If i = numChunks Then
        crypt.LastChunk = True
    End If


    '  Read the next chunk from the file.
    '  The last chunk will be whatever amount remains in the file..
    bd.Clear
    facIn.FileReadBd(chunkSize, bd)

    '  Decrypt this chunk.
    crypt.DecryptBd(bd)
    '  Accumulate the decrypted chunks.
    bdDecrypted.AppendBd(bd)

    crypt.FirstChunk = False
Loop

'  Make sure both FirstChunk and LastChunk are restored to True after
'  encrypting or decrypting in chunks.  Otherwise subsequent encryptions/decryptions
'  will produce unexpected results.
crypt.FirstChunk = True
crypt.LastChunk = True

facIn.FileClose

'  The fully decrypted file is contained in bdDecrypted.
'  You can save to a file if desired, or use the decrypted data in your application directly from bdDecrypted.
bdDecrypted.WriteFile("c:/temp/qa_output/hamlet_decrypted.xml")