B4X Requires Chilkat v11.0.0+

Verify Opaque Signature and Retrieve Signing Certificates

See more Digital Signatures Examples

Demonstrates how to verify a PCKS7 opaque digital signature (signed data), extract the original file/data, and then extract the certificate(s) that were used to sign. B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")

'  Verify a PKCS7 signed-data (opaque signature) file and extract the original content to a file.
success = crypt.VerifyP7M("qa_data/p7m/opaqueSig.p7", "qa_output/originalData.dat")
If success = False Then
    Log(crypt.LastErrorText)
    Return
End If


'  Alternatively, we can do it in memory...
Dim binData As ChilkatBinData
binData.Initialize
success = binData.LoadFile("qa_data/p7m/opaqueSig.p7")
'  Your app should check for success, but we'll skip the check for brevity..

'  If verified, the signature is unwrapped and binData is replaced with the original data that was signed.
success = crypt.OpaqueVerifyBd(binData)
If success = False Then
    Log(crypt.LastErrorText)
    Return
End If


'  For our testing, we signed some text, so we can get it from the binData..
Log("Original Data:")
Log(binData.GetString("utf-8"))

'  After any method call that verifies a signature, the crypt object will contain the certificate(s)
'  that were used for signing (assuming the X.509 certs were available in the signature, which is typically the case).

'  Get each signing certificate, and build the certificate chain for each.
Dim cert As ChilkatCert
cert.Initialize("cert")
Dim certChain As ChilkatCertChain
certChain.Initialize
Dim numCerts As Int = crypt.NumSignerCerts
Dim i As Int = 0
Do While i < numCerts
    crypt.LastSignerCert(i, cert)
    Log(cert.SubjectDN)

    success = cert.BuildCertChain(certChain)
    If success = False Then
        Log(cert.LastErrorText)
        Return
    End If


    i = i + 1
Loop