B4X

Load .crl, Convert to XML, Get Revoked Serial Numbers and Dates

See more Certificates Examples

Load a binary .crl file (Certificate Revocation List), converts to XML, and then gets the revoked certificate serial numbers and revocation dates.

Note: This example requires Chilkat v9.5.0.77 or greater.

B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  Load a binary .crl file.
Dim bdCrl As ChilkatBinData
bdCrl.Initialize
success = bdCrl.LoadFile("qa_data/crl/ca1.crl")
If success <> True Then
    Log("Failed to load CRL file.")
    Return
End If


Dim asn As ChilkatAsn
asn.Initialize
success = asn.LoadBd(bdCrl)
If success <> True Then
    Log(asn.LastErrorText)
    Return
End If


'  Convert ASN.1 to XML and load into xml and re-emit for pretty printing..
Dim xml As ChilkatXml
xml.Initialize
xml.LoadXml(asn.AsnToXml)
success = xml.SaveXml("qa_output/crl.xml")

'  Use this online tool to generate parsing code from CRL XML: 
'  Generate Parsing Code from XML

'  Here's code to parse the XML.  This code was generated by the above tool,
'  and then we modified it by removing unneeded code and changing some names
Dim i As Int
Dim count_i As Int
Dim tagPath As String
Dim j As Int
Dim count_j As Int
Dim k As Int
Dim count_k As Int

Dim revokedCertSerialHex As String
Dim dateRevoked As String

Dim dt As ChilkatDateTime
dt.Initialize

i = 0
count_i = xml.NumChildrenHavingTag("sequence")
Do While i < count_i
    xml.I = i

    j = 0
    count_j = xml.NumChildrenHavingTag("sequence[i]|sequence")
    Do While j < count_j
        xml.J = j

        k = 0
        count_k = xml.NumChildrenHavingTag("sequence[i]|sequence[j]|sequence")
        Do While k < count_k
            xml.K = k

            '  Get the revoked certificate's serial number in uppercase hex.
            revokedCertSerialHex = xml.GetChildContent("sequence[i]|sequence[j]|sequence[k]|int")
            Log("serial number: " & revokedCertSerialHex)

            '  Get the date/time revoked.  It will be a string formatted as "YYMMDDhhmmssZ", such as "181023093028Z"
            dateRevoked = xml.GetChildContent("sequence[i]|sequence[j]|sequence[k]|utctime")

            '  Starting in Chilkat v9.5.0.77, date/time strings formatted as YYMMDDhhmmssZ can be parsed as follows:
            dt.SetFromTimestamp(dateRevoked)
            Log("date revoked: " & dt.GetAsRfc822(False))

            k = k + 1
        Loop
        j = j + 1
    Loop
    i = i + 1
Loop