B4X

Create CMS Signed File (PDF) with Multiple Signing Certificates

See more Digital Signatures Examples

Demonstrates how to sign a file by adding multiple signatures (multiple certificates). This example signs a PDF file to produce an output file that is a CMS signature wrapping the original PDF. (Note: This is different than modifying a PDF by injecting a signature into the PDF file format.)

Note: This example requires Chilkat v9.5.0.83 or greater.

B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")

'  ------------ This example requires Chilkat v9.5.0.83 or greater.

Dim cert1 As ChilkatCert
cert1.Initialize("cert1")
success = cert1.LoadPfxFile("qa_data/pfx/cert_test123.pfx", "test123")
If success <> True Then
    Log(cert1.LastErrorText)
    Return
End If


Dim cert2 As ChilkatCert
cert2.Initialize("cert2")
success = cert2.LoadPfxFile("qa_data/pfx/test_secret.pfx", "secret")
If success <> True Then
    Log(cert2.LastErrorText)
    Return
End If


'  ------------ This example requires Chilkat v9.5.0.83 or greater.

'  Tell the crypt component to use both certificates for signing. 
'  When we create the signature, it will be signed by both certificates.
success = crypt.AddSigningCert(cert1)
If success <> True Then
    Log(crypt.LastErrorText)
    Return
End If

success = crypt.AddSigningCert(cert2)
If success <> True Then
    Log(crypt.LastErrorText)
    Return
End If


'  The CadesEnabled property applies to all methods that create PKCS7 signatures. 
'  To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = True

crypt.HashAlgorithm = "sha256"

'  We can sign any type of file, creating a .p7s as output.
'  The .p7s contains the signature and also embeds the data of the file that is signed.
Dim inFile As String = "qa_data/pdf/sample.pdf"
Dim p7sFile As String = "qa_output/sample.pdf.p7s"

'  Create the CAdES-BES attached signature, which contains the original data.
'  Note: Chilkat's function naming is not accurate.  CreateP7M creates a PKCS7 signature where the signed file
'  is contained within the signature.  CreateP7S creates a detached PKCS7 signature where the signed file
'  is NOT contained within the signature.  We want the data to be contained in the signature, therefore
'  we call CreateP7M even though we are naming our output file .p7s.
success = crypt.CreateP7M(inFile, p7sFile)
If success = False Then
    Log(crypt.LastErrorText)
    Return
End If


'  Verify the .p7s file and extract the original file from the .p7s. 
Dim extractedToFilePath As String = "qa_output/sample.pdf"
success = crypt.VerifyP7M(p7sFile, extractedToFilePath)
If success = False Then
    Log(crypt.LastErrorText)
    Return
End If


Log("Success!")