B4X

Certify a PDF and Lock the Entire Document

See more PDF Signatures Examples

This example demonstrates how to a sign a certify a PDF and lock the entire document. Normally this is intended to seal the document with a final approving (or dissapproving) signature; usually after a review workflow is completed and normally reserved for the creator or author of a document. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim pdf As ChilkatPdf
pdf.Initialize("pdf")

'  Load a PDF to be certified and locked.
'  The "hello.pdf" is available at https://chilkatsoft.com/hello.pdf
success = pdf.LoadFile("qa_data/pdf/hello.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


'  Options for signing are specified in JSON.
Dim json As ChilkatJsonObject
json.Initialize

'  In most cases, the signingCertificateV2 and signingTime attributes are required.
json.UpdateInt("signingCertificateV2", 1)
json.UpdateInt("signingTime", 1)

'  The only coding difference with certifying and locking a PDF
'  as compared with an approval signature (also known as recipient signature)
'  is to add the "lockAfterSigning" and "docMDP.add" to the json.
json.UpdateBool("lockAfterSigning", True)
json.UpdateBool("docMDP.add", True)

'  Put the signature on page 1, top left
json.UpdateInt("page", 1)
json.UpdateString("appearance.y", "top")
json.UpdateString("appearance.x", "left")

'  Use a font scale of 10.0
json.UpdateString("appearance.fontScale", "10.0")

'  In this example, the appearance of the digital signature will contain three lines:
'  1) The signing certificate's common name
'  2) The current date/time
'  3) Some arbitrary text.
'  The keyword "cert_cn" is replaced with the Certificate's Subject Common Name.
'  The keyword "current_dt" is replaced with the current date/time.
'  Any number of appearance text lines can be added.
json.UpdateString("appearance.text[0]", "Digitally signed by: cert_cn")
json.UpdateString("appearance.text[1]", "current_dt")
json.UpdateString("appearance.text[2]", "The crazy brown fox jumps over the lazy dog.")

'  Load the signing certificate. (Use your own certificate.)
Dim cert As ChilkatCert
cert.Initialize("cert")
success = cert.LoadPfxFile("qa_data/pfx/myPdfSigningCert.pfx", "secret")
If success = False Then
    Log(cert.LastErrorText)
    Return
End If


'  Tell the pdf object to use the certificate for signing.
success = pdf.SetSigningCert(cert)
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


success = pdf.SignPdf(json, "qa_output/hello_signed.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


Log("The PDF has been successfully certified and locked.")