B4X Requires Chilkat v11.4.0+
B4X
Streaming AI with Automatic JavaScript AI Tool Function Calling
See more AI Examples
Demonstrates how to get AI responses in streaming mode, including possible tool function calling using Chilkat with embedded Chilkat.Js JavaScript. Automatic JavaScript tool calls are characterized by:- Tool function implementations are in JavaScript.
- The JavaScript also provides a tool registry and permissions.
- The JavaScript runs embedded within your application using Chilkat.Js.
- Tool calls are handled entirely within Chilkat. Your application does not need to manually check for function calls in the AI response. Internal to the Ask function, Chilkat will handle function calls by calling your registered JavaScript tools and will send results back to the AI model until the final response is received.
Chilkat B4X Downloads
Dim success As Boolean = False
' ----------------------------------------------------------------------------------
' The Javascript file loaded here is shown at the bottom of this page.
' -----------------------------------------------------------------------------------
Dim sbJs As ChilkatStringBuilder
sbJs.Initialize
success = sbJs.LoadFile("qa_data/js_tools/horoscope_tools.js", "utf-8")
If success = False Then
Log(sbJs.LastErrorText)
Return
End If
Dim ai As ChilkatAi
ai.Initialize("ai")
' Register the tools that will be made available to the AI.
Dim evalOnly As Boolean = False
Dim allowAllKeyword As Boolean = True
ai.RegisterJsTools(sbJs, evalOnly, allowAllKeyword)
' The provider can be "openai", "google", "claude", "grok", "mistral", "custom", etc.
ai.Provider = "openai"
' Use your provider's API key.
ai.ApiKey = "MY_API_KEY"
' Choose a model.
ai.Model = "gpt-5.6-luna"
' Tool function calling must always occur within a conversation.
Dim conversation_name As String = "convo_astrology"
Dim sysMessage As String = "You are a helpful astrologer"
Dim devMessage As String = "Respond only with markdown."
ai.NewConvo(conversation_name, sysMessage, devMessage)
' Provide inputs
ai.InputAddText("What is my horoscope? I am an Aquarius.")
' Get the response in streaming mode.
ai.Streaming = True
' In streaming mode, if we receive an AI event that is a request for tool use,
' we'll need to make the call to the JavaScript and then continue with a followup Ask,
' until the final response is received.
Dim sbEventName As ChilkatStringBuilder
sbEventName.Initialize
Dim sbDelta As ChilkatStringBuilder
sbDelta.Initialize
Dim sbFullResponse As ChilkatStringBuilder
sbFullResponse.Initialize
' When PollAi returns with an event, it's highly unlikely the
' call to NextAiEvent does not immediately return. Setting a max
' timeout is just a precaution..
Dim maxWaitMs As Int = 5000
Dim finished As Boolean = False
Dim numAsks As Int = 0
' Set a max # of followup Asks to prevent any unexpected infinite looping.
Do While Not(finished) And (numAsks < 10)
' Send the request to the AI model.
success = ai.Ask("text")
If success = False Then
Log(ai.LastErrorText)
Return
End If
Dim madeFunctionCalls As Boolean = False
Dim streamingDone As Boolean = False
Do While Not(streamingDone)
Dim result As Int = ai.PollAi(False)
If result < 0 Then
Log(ai.LastErrorText)
Log("Failed.")
Return
End If
If result > 0 Then
' We have an event..
success = ai.NextAiEvent(maxWaitMs, sbEventName, sbDelta)
If success = False Then
Log(ai.LastErrorText)
Return
End If
' Is this an event where the AI is requesting a function call?
If sbEventName.ContentsEqual("js_function_call", True) Then
' Call the JavaScript function.
' We don't need to find the exact function and make the call.
' We can simply pass the sbDelta (which contains information about the function to be called and the args).
' Chilkat will find the registered JavaScript function, call it, and add the results to the conversation.
' We indicate that function calls were made, which results in a followup Ask (in the outer loop).
success = ai.StreamingJsToolCall(sbDelta)
If success = False Then
' The JS function call failed.
streamingDone = True
Else
madeFunctionCalls = True
End If
Else
If Not(sbEventName.ContentsEqual("empty", True)) Then
sbFullResponse.AppendSb(sbDelta)
If sbEventName.ContentsEqual("null_terminator", True) Then
streamingDone = True
End If
End If
End If
Else
' No event arrived, so wait a short time rather than spin in a loop..
ai.SleepMs(100)
End If
Loop
If Not(madeFunctionCalls) Then
finished = True
End If
numAsks = numAsks + 1
Loop
Log("Full Response:")
Log(sbFullResponse.GetAsString)
// The namespace for the AI tool functions in this JavaScript source file.
// You must provide a namespace.
Example = {};
// ----------------------------
// Tool implementation functions
// -----------------------------
// Tool functions must ALWAYS have just a single argument, which is an object.
// The function name used here must match the "name" in the toolRegistry below.
// By grouping get_compatibility, get_horoscope, toolRegistry, and toolPermissions under the Example object,
// you are "namespacing" them. This tells anyone reading the code (and the JavaScript engine itself)
// that these tools belong together and prevents them from clashing with another function that might
// also be named get_horoscope.
Example.get_compatibility = function(arg) {
return `${arg.sign1} is compatible with ${arg.sign2} in a ${arg.relationship_type} way.`;
}
Example.get_horoscope = function(arg) {
return `${arg.sign} : Next Tuesday you will befriend a baby otter.`;
}
// -------------
// Tool Registry
// -------------
// The inputSchema.type must ALWAYS be "object".
// Use this format regardless of the AI provider (ChatGPT, Gemini, Claude, Grok, Mistral, etc.)
Example.toolRegistry = [
{
name: "get_horoscope",
description: "Get today's horoscope for an astrological sign.",
parameters: {
properties: {
sign: { type: "string", description: "An astrological sign like Taurus or Aquarius" }
},
}
},
{
name: "get_compatibility",
description: "Returns compatibility analysis between two zodiac signs, including a score and explanation.",
parameters: {
properties: {
sign1: {
type: "string", description: "The first zodiac sign (e.g., Aries, Taurus, Gemini)."
},
sign2: {
type: "string", description: "The second zodiac sign (e.g., Aries, Taurus, Gemini)."
},
relationship_type: {
type: "string", description: "Type of compatibility to evaluate. (e.g., romantic, friendship, professional, general)"
},
detail_level: {
type: "string", description: "Level of detail in the response. (e.g., short, medium, detailed)"
}
}
}
}
];
Example.toolPermissions = [
{
name: "all",
perm: "sandbox",
}
];
// Return the name of this toolset
// This tells Chilkat the namespace of this toolset.
"Example";