B4X

AES and CHACHA20 Encrypt/Decrypt Text

See more Encryption Examples

Demonstrates the use of the new EncryptSb and DecryptSb methods introduced in Chilkat v9.5.0.67 to encrypt/decrypt the contents of StringBuilder objects.

Note: This example requires Chilkat v9.5.0.67 or greater.

B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  First build a string to be encrypted
Dim sb As ChilkatStringBuilder
sb.Initialize
Dim i As Int = 1
Do While i < 10
    sb.AppendInt(i)
    sb.Append(" the quick brown fox jumped over the lazy dog." & Chr(13) & Chr(10))
    i = i + 1
Loop

Log(sb.GetAsString)

'  The string to be encrypted looks like this:

'  1 the quick brown fox jumped over the lazy dog.
'  2 the quick brown fox jumped over the lazy dog.
'  3 the quick brown fox jumped over the lazy dog.
'  4 the quick brown fox jumped over the lazy dog.
'  5 the quick brown fox jumped over the lazy dog.
'  6 the quick brown fox jumped over the lazy dog.
'  ...

Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")

'  Specify the encryption to be used.
'  First we'll do AES-128 CBC
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

Dim ivHex As String = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedIV(ivHex, "hex")

Dim keyHex As String = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey(keyHex, "hex")

'  When EncryptSb is called, the contents of the source (sb)
'  remains unmodified.  The encrypted bytes are written into bdEncrypted.
'  If bdEncrypted already contained data, it is replaced with the encrypted bytes.
Dim bdEncrypted As ChilkatBinData
bdEncrypted.Initialize
success = crypt.EncryptSb(sb, bdEncrypted)
If success <> True Then
    Log(crypt.LastErrorText)
    Return
End If


'  Examine the encrypted bytes:
Log(bdEncrypted.GetEncoded("base64_mime"))

'  Sample encrypted data:

'  0DdNZ22ckMMJBiaKhAu3wUEfh16XW356NIUsDmNs/xwbHe/p1201OmpfzwXwKktkAefu2pckrBgC
'  df+1w8lRo+KAy5n5wlAgMGM/UrsVJsp0BmDPk1vaxKrmrGpSXOVCQs1n2+0atIs5YLiOG+Va3+Mi
'  EQNb4YK7bNMmvt0++irBxTiGnkx/RncfKwgkbBUpl2x7yV13MW6lapDT6Md0DKAMsTXFJYGeIdEf
'  g2uxDDQzI5gUOUHTMrXQ8paD/K76KKB9Jpp/kAM9z8g/d8KUmuphA7KI64d38xsgOmcITlbhlCQ2
'  PDkcU6RRzX0FUTUSMgQukhy0jkLZEjHX9poKJD+iJTOkcQUC3OqR9hKhSrvIgJN4lxdR71MheOoQ
'  2wmvRdq+agTWWh333Vmb6J6yDV79aSpnqEDrA8Ks7Xzciol0gve91+JtVJlJKjWwEzWEU8GxF7Q8
'  eaWI70lsC5nTLGcbqgKu6gzkzHlHyHaE2FAQA/d5I2dvfsAYUQCza0Zdyw8mmTtHhlP2Tfxj1uPv
'  H4Q7BGuKnx3SWT2CnpbX4091w7KzLAztrbFBo/Tf9w8ZpgTK9k1ryfW9/xnk6rW6iQ==

'  Decrypt to restore back to the original:
Dim sbOriginal As ChilkatStringBuilder
sbOriginal.Initialize
success = crypt.DecryptSb(bdEncrypted, sbOriginal)
If success <> True Then
    Log(crypt.LastErrorText)
    Return
End If


'  Examine the original data:
Log(sbOriginal.GetAsString)

'  ----------------------------------------------------------------------------------
'  To do chacha20 encryption, just change the settings:

crypt.CryptAlgorithm = "chacha20"
crypt.KeyLength = 256
'  The initial count is the initial block counter for the chacha20 algorithm.
'  It can be any integer, but must be set to the same when decrypting.
crypt.InitialCount = 22

'  EncryptSb completely replaces the contents of bdEncrypted.
success = crypt.EncryptSb(sb, bdEncrypted)

'  However.. DecryptSb appends the decrypted text to whatever may
'  have already existed within sbOriginal.
success = crypt.DecryptSb(bdEncrypted, sbOriginal)

Log("----")
Log("The original data should be here twice.  Once from the AES decrypt, and again from the chacha20 decrypt.")
Log(sbOriginal.GetAsString)
Log("Success.")