B4X

Send Encrypted Email with a Selected Algorithm (AES, 3DES, etc.)

Sends an encrypted email using the recipient's digital certificate from a .cer file, and chooses 3DES for the encryption algorithm. (It is also possible to send AES encrypted email w/ 128-bit, 192-bit, or 256-bit encryption simply by setting the Pkcs7CryptAlg and Pkcs7KeyLength properties.) B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The mailman object is used for sending and receiving email.
Dim mailman As ChilkatMailMan
mailman.Initialize("mailman")

'  Set the SMTP server.
mailman.SmtpHost = "smtp.mymailserver.com"

'  Load the .cer file into a certificate object.
'  When sending S/MIME encrypted email, it is the recipient's
'  certificate that is used for encryption.  Only the public key
'  is needed to encrypt.  The recipient is the only
'  one possessing the private key, and therefore is the only
'  one able to decrypt.
Dim cert As ChilkatCert
cert.Initialize("cert")
success = cert.LoadFromFile("cknotes.cer")
If success <> True Then
    Log(cert.LastErrorText)
    Return
End If


'  Create a new email object
Dim email As ChilkatEmail
email.Initialize

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Chilkat Support <support@chilkatsoft.com>"
success = email.AddTo("Chilkat Blog", "admin@cknotes.com")

'  Indicate that the email is to be sent encrypted.
email.SendEncrypted = True

'  Specify the certificate to be used for encryption.
success = email.SetEncryptCert(cert)

'  If desired, specify the encryption algorithm to be used.
'  The Pkcs7CryptAlg property can be set to "aes", "des", "3des", or "rc2"
email.Pkcs7CryptAlg = "3des"

'  If desired, set the key length (in bits) for the encryption algorithm:
'  The possible values allowed depend on the Pkcs7CryptAlg property. 
'  For "aes", the key length may be 128, 192, or 256. 
'  For "3des" the key length must be 192. 
'  For "des" the key length must be 40. 
'  For "rc2" the key length can be 40, 56, 64, or 128.
email.Pkcs7KeyLength = 192

success = mailman.SendEmail(email)
If success <> True Then
    Log(mailman.LastErrorText)
Else
    Log("Mail Sent!")
End If