Classic ASP
Socket Send and Receive BinData

Demonstrates the Chilkat Socket ReceiveBdN and SendBd methods.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set sock = Server.CreateObject("Chilkat.Socket")

' --------------------------------------------------------------------
' This example uses the public TCP echo service at https://tcpbin.com/
' --------------------------------------------------------------------

useTls = 0
port = 4242
maxWaitMs = 5000
success = sock.Connect("tcpbin.com",port,useTls,maxWaitMs)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( sock.LastErrorText) & "</pre>"
    Response.End
End If

' Wait a max of 2 seconds for a response..
sock.MaxReadIdleMs = 2000

' Send 26 bytes contained in a Chilkat BinData
set bdToSend = Server.CreateObject("Chilkat.BinData")
i = 0
byteVal = 65
Do While i < 26
    success = bdToSend.AppendByte(byteVal)
    byteVal = byteVal + 1
    i = i + 1
Loop
' Send the contents of the BinData
' Pass zero's in the 2nd and 3rd arguments to send the entire contents of the BinData.
success = sock.SendBd(bdToSend,0,0)

' The tcpbin.com echo server only echoes after receiving an LF (linefeed char)
success = sock.SendByte(10)

' The echo server will echo back whatever is sent to it.
' We should be able to read the same bytes back..
set bdRecv = Server.CreateObject("Chilkat.BinData")
' Receive the 26 bytes previously sent, plus the LF char.
success = sock.ReceiveBdN(27,bdRecv)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( sock.LastErrorText) & "</pre>"
    Response.End
End If

' Show the contents of bdRecv in hex format
Response.Write "<pre>" & Server.HTMLEncode( bdRecv.GetEncoded("hex")) & "</pre>"

' Output:  4142434445464748494A4B4C4D4E4F505152535455565758595A0A

%>
</body>
</html>