Classic ASP
REST Basic Auth with Secure Strings

Demonstrates how to do REST Basic authentication using secure strings.
This example requires Chilkat v9.5.0.71 or greater.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Imagine we've previously saved our encrypted login and password within a JSON config file
' that contains this:

' {
'   "http_login": "mCrOmA7mBA7Au9RuJGb9hw==",
'   "http_password": "jJtiI9TgErTTpqBz9JtHBw=="
' }

set json = Server.CreateObject("Chilkat.JsonObject")
success = json.LoadFile("qa_data/passwords/http.json")

set crypt = Server.CreateObject("Chilkat.Crypt2")

' These are the encryption settings we previously used to encrypt the credentials within the JSON config file.
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128
crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"
crypt.EncodingMode = "base64"

set ssLogin = Server.CreateObject("Chilkat.SecureString")
set ssPassword = Server.CreateObject("Chilkat.SecureString")

' Decrypt to the secure string.  (the strings will still held in memory encrypted, but are now encrypted using
' a randomly generated session key.)
success = crypt.DecryptSecureENC(json.StringOf("http_login"),ssLogin)
success = crypt.DecryptSecureENC(json.StringOf("http_password"),ssPassword)

set rest = Server.CreateObject("Chilkat.Rest")

' Connect to a REST server.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("chilkatsoft.com",port,bTls,bAutoReconnect)

' Cause the "Authorization: Basic ..." header to be added to HTTP requests
success = rest.SetAuthBasicSecure(ssLogin,ssPassword)

responseJson = rest.FullRequestNoBody("GET","/helloWorld.html")
If (rest.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

' Show the LastRequestHeader that was sent.
Response.Write "<pre>" & Server.HTMLEncode( rest.LastRequestHeader) & "</pre>"

' The LastRequestHeader looks like this:

' Host: chilkatsoft.com
' Authorization: Basic bXlIdHRwTG9naW46bXlIdHRwUGFzc3dvcmQ=

%>
</body>
</html>