Classic ASP

Encrypt a File to a PKCS7 (CMS) Message

Shows how to encrypt a file into a PKCS7 encrypted message using the recipient's certificate. Public-key encryption requires no private key. However, the recipient's private key is necessary for decryption.

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = Server.CreateObject("Chilkat.Crypt2")

' Load the recipient's digital certificate. 
' We don't need the private key for encryption.
' Only the public key is needed (which is included in a certificate).
set cert1 = Server.CreateObject("Chilkat.Cert")
success = cert1.LoadFromFile("qa_data/user1/cert_user1.pem")
' Assume success for the example, but make sure your application checks for success/failure...
success = crypt.SetEncryptCert(cert1)

' Indicate that we want PKI encryption (i.e. public-key infrastructure)
' to produce a CMS message (Cryptographic Message Syntax/PKCS7),
' that is be created with RSAES-OAEP padding, SHA256, and AES-256 for the
' bulk encryption.
crypt.CryptAlgorithm = "pki"
crypt.Pkcs7CryptAlg = "aes"
crypt.KeyLength = 256
crypt.OaepHash = "sha256"
crypt.OaepPadding = 1

' Load the file to be encrypted...
set fileData = Server.CreateObject("Chilkat.BinData")
success = fileData.LoadFile("qa_data/jpg/penguins.jpg")
' Your app should check for success/failure..

' Encrypt the data.  The contents of the fileData object are replaced with the PKCS7 encrypted message.
success = crypt.EncryptBd(fileData)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( crypt.LastErrorText) & "</pre>"
    Response.End
End If

' Save the PKCS7 encrypted message to a file..
success = fileData.WriteFile("qa_output/pkcs7_encrypted.p7")

Response.Write "<pre>" & Server.HTMLEncode( "OK.") & "</pre>"

%>
</body>
</html>