Classic ASP

Verify and Pin the FTPS Server Certificate

Demonstrates the certificate-verification properties RequireSslCertVerify, TlsPinSet, and the read-only SslServerCertVerified.

Background: By default a TLS connection is not rejected merely because certificate-chain verification fails, so RequireSslCertVerify = true is the important hardening step — it makes an expired, unsigned, or untrusted certificate abort the connection. TlsPinSet adds public-key pinning on top: the handshake fails unless the server's SPKI fingerprint matches one you configured, defending against a mis-issued certificate that would otherwise validate. Pinning supplements verification rather than replacing it. SslServerCertVerified reports the outcome.

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

set ftp = Server.CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "myFtpLogin"

ftp.AuthTls = 1

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
ftp.Password = "myPassword"

'  Reject the connection if the server certificate cannot be verified (expired, bad signature,
'  untrusted chain, etc.).  The default is 0, which does not reject on verification
'  failure -- set 1 for security.
ftp.RequireSslCertVerify = 1

'  Optionally pin the server's public key.  If none of the configured SPKI fingerprints matches,
'  the TLS handshake fails.  Pinning supplements normal verification; it does not replace it.
ftp.TlsPinSet = "sha256//YLh1dUR9y6Kja30RrAn7JKnbQG/uEtLMkBgFF2Fuihg="

success = ftp.Connect()
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If

'  SslServerCertVerified reports whether the certificate chain was successfully verified.
If (ftp.SslServerCertVerified) Then
    Response.Write "<pre>" & Server.HTMLEncode( "The server certificate was verified.") & "</pre>"
End If

success = ftp.Disconnect()
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If


%>
</body>
</html>