Classic ASP

Get an FTP Listing Entry's Permissions

Demonstrates the Chilkat Ftp2.GetPermissions method, which returns the permissions or status string of a cached directory-listing entry. The only argument is a zero-based index. The value is empty when the server provides no such metadata.

Background: FTP has no single standard permissions format, so what this returns depends on the server — commonly a Unix-style mode string like drwxr-xr-x, but potentially something else. Because the format varies, pair it with GetPermType to learn how to interpret the string before parsing it, rather than assuming a fixed layout.

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

'  Demonstrates the Ftp2.GetPermissions method, which returns the permissions or status string of
'  a cached directory-listing entry.  The only argument is a zero-based index.

set ftp = Server.CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "myFtpLogin"

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
ftp.Password = "myPassword"

success = ftp.Connect()
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If

success = ftp.ChangeRemoteDir("public_html")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If

'  GetDirCount retrieves the directory listing on the first call and returns the number of
'  entries.  A negative return indicates failure.
n = ftp.GetDirCount()
If (n < 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If

For i = 0 To n - 1
    name = ftp.GetFilename(i)

    '  The permissions string is empty when the server provides no such metadata.  Use
    '  GetPermType to learn how to interpret the string's format.
    perms = ftp.GetPermissions(i)
    Response.Write "<pre>" & Server.HTMLEncode( perms & "  " & name) & "</pre>"
Next

success = ftp.Disconnect()
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If


%>
</body>
</html>