Classic ASP
Example: Http.HttpReq method

Demonstrates how to call the HttpReq method.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

set http = Server.CreateObject("Chilkat.Http")
success = 0

' This example will send an HTTP POST with the body of the HTTP request containing JSON.

' Create the following JSON: { "name": "Harry", "state": "FL" }

set json = Server.CreateObject("Chilkat.JsonObject")
success = json.UpdateString("name","Harry")
success = json.UpdateString("state","FL")

' Specify the details of the request
set req = Server.CreateObject("Chilkat.HttpRequest")

req.HttpVerb = "POST"
req.ContentType = "application/json"
success = req.LoadBodyFromString(json.Emit(),"utf-8")

' Send the charset attribute in the HTTP request header.
req.SendCharset = 1
req.Charset = "utf-8"

' Send the POST
' You can send the POST to the URL below.  
' The response will contain the raw body of the request that was sent.
' (i.e. everything except the HTTP request header).

set resp = Server.CreateObject("Chilkat.HttpResponse")
success = http.HttpReq("https://www.chilkatsoft.com/echo_request_body.asp",req,resp)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

' Examine the HTTP request header we sent:
Response.Write "<pre>" & Server.HTMLEncode( http.LastHeader) & "</pre>"

' The response body contains the raw content of the HTTP request body we sent.
Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"

' Sample output:

' POST /echo_request_body.asp HTTP/1.1
' Host: www.chilkatsoft.com
' Content-Type: application/json; charset=utf-8
' Content-Length: 29
' 
' 
' {"name":"Harry","state":"FL"}

%>
</body>
</html>