Classic ASP

Get a Header Attribute of an Attached Message

Demonstrates the Chilkat Email.GetAttachedMessageAttr method, which returns a header-field attribute value for the Nth attached (embedded) email. The first argument is the zero-based attached-message index, the second is the header field name, and the third is the attribute name. This example attaches an email and reads the filename attribute of its Content-Disposition header.

Background: MIME header fields can carry named attributes (parameters) after the main value — for example Content-Disposition: attachment; filename="report.eml", where filename is an attribute. Rather than parsing the raw header yourself, this method extracts a single named attribute from a chosen header of a specific embedded message, which is convenient when a message forwards other emails as nested message/rfc822 parts.

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

'  Demonstrates the GetAttachedMessageAttr method, which returns a header-field attribute
'  value for the Nth attached (embedded) email.  The first argument is the zero-based
'  attached-message index, the second is the header field name, and the third is the attribute name.

'  Build an inner email to attach.
set innerEmail = Server.CreateObject("Chilkat.Email")
innerEmail.Subject = "Embedded message"
innerEmail.From = "alice@example.com"
success = innerEmail.AddTo("Bob","bob@example.com")

'  Attach it to an outer email as a message/rfc822 part.
set email = Server.CreateObject("Chilkat.Email")
email.Subject = "Has an attached message"
success = email.AttachEmail(innerEmail)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( email.LastErrorText) & "</pre>"
    Response.End
End If

'  Get the "filename" attribute of the "Content-Disposition" header of the first
'  attached message (index 0).
fname = email.GetAttachedMessageAttr(0,"Content-Disposition","filename")
Response.Write "<pre>" & Server.HTMLEncode( "Attached message filename attribute: " & fname) & "</pre>"

%>
</body>
</html>