Classic ASP
How to Generate an Azure Service Bus Shared Access Signature (SAS)

Demonstrates generating and using an Azure Service Bus Shared Access Signature (SAS).
Note: This example requires Chilkat v9.5.0.65 or greater.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' Note: Requires Chilkat v9.5.0.65 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' -------------------------------------------------------------------
' Create a Shared Access Signature (SAS) token for Azure Service Bus.
' -------------------------------------------------------------------

set authSas = Server.CreateObject("Chilkat.AuthAzureSAS")
authSas.AccessKey = "AzureServiceBus_PrimaryKey"

' The SAS token for Service Bus will look like this:
' (The order of params will be different.  The order does not matter.)
' sig=<signature-string>&se=<expiry>&skn=<keyName>&sr=<URL-encoded-resourceURI>

' Specify the format of the string to sign.
authSas.StringToSign = "resourceURI,expiry"

' Create an expiry to 30 days in the future.
set dtExpiry = Server.CreateObject("Chilkat.CkDateTime")
success = dtExpiry.SetFromCurrentSystemTime()
success = dtExpiry.AddDays(30)
success = authSas.SetTokenParam("expiry","se",dtExpiry.GetAsUnixTimeStr(1))

' Set the skn (keyname)
' This example uses the key "RootManageSharedAccessKey".  This give full access.
' In a typical scenario, you would create a new Azure key (for the service bus)
' in the Azure portal, such that the key has limited permissions.  This would
' allow you to give the SAS token to others for specific access for some period of time.
success = authSas.SetTokenParam("keyName","skn","RootManageSharedAccessKey")

' Set the URL-encoded-resourceURI
set sbResourceUri = Server.CreateObject("Chilkat.StringBuilder")
success = sbResourceUri.Append("https://<yournamespace>.servicebus.windows.net/")
success = sbResourceUri.Encode("url","utf-8")
success = authSas.SetTokenParam("resourceURI","sr",sbResourceUri.GetAsString())

' Generate the SAS token.
sasToken = authSas.GenerateToken()
If (authSas.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( authSas.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "SAS token: " & sasToken) & "</pre>"

' Save the SAS token to a file.
' We can then use this pre-generated token for future Service Bus operations.
set fac = Server.CreateObject("Chilkat.FileAccess")
success = fac.WriteEntireTextFile("qa_data/tokens/serviceBusSas.txt",sasToken,"utf-8",0)

%>
</body>
</html>