Classic ASP

SSL Client Example

Demonstrates how to connect to an SSL server, send a simple message, receive a simple response, and disconnect.

Chilkat Classic ASP Downloads

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set socket = Server.CreateObject("Chilkat.Socket")

ssl = 1
maxWaitMillisec = 20000

' The SSL server hostname may be an IP address, a domain name,
' or "localhost".  You'll need to change this:

sslServerHost = "123.123.88.88"
sslServerPort = 8123

' Connect to the SSL server:
success = socket.Connect(sslServerHost,sslServerPort,ssl,maxWaitMillisec)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( socket.LastErrorText) & "</pre>"
    Response.End
End If

' Set maximum timeouts for reading an writing (in millisec)
socket.MaxReadIdleMs = 20000
socket.MaxSendIdleMs = 20000

' Send a "Hello Server! -EOM-" message:
success = socket.SendString("Hello Server! -EOM-")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( socket.LastErrorText) & "</pre>"
    Response.End
End If

' The server (in this example) is going to send a "Hello Client! -EOM-" 
' message.  Read it:
receivedMsg = socket.ReceiveUntilMatch("-EOM-")
If (socket.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( socket.LastErrorText) & "</pre>"
    Response.End
End If

' Close the connection with the server
' Wait a max of 20 seconds (20000 millsec)
success = socket.Close(20000)

Response.Write "<pre>" & Server.HTMLEncode( receivedMsg) & "</pre>"

%>
</body>
</html>