Classic ASP
SSH Tunnel (Port Forwarding via direct-tcpip channel)

Demonstrates how to create an SSH tunnel to a remote hostname:port via a direct-tcpip channel.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ssh = Server.CreateObject("Chilkat.Ssh")

' Connect to an SSH server:

' Hostname may be an IP address or hostname:
hostname = "192.168.1.117"
port = 22

success = ssh.Connect(hostname,port)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ssh.LastErrorText) & "</pre>"
    Response.End
End If

' Wait a max of 5 seconds when reading responses..
ssh.IdleTimeoutMs = 5000

' Authenticate using login/password:
success = ssh.AuthenticatePw("chilkat","myPassword")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ssh.LastErrorText) & "</pre>"
    Response.End
End If

' Open a direct-tcpip channel.  We want the SSH server to connect
' to www.chilkatsoft.com, port 80 (i.e. the web server).
' Data sent through the SSH tunnel is forwarded to the remote
' host:port.  (Note: The remote host:port does not need to be 
' a web server.  It can be anything.  It can be your own
' customer application server that listens on a port, or any
' other type of server.)
' When we read from the SSH channel, we'll be reading data
' sent from the remote host:port (i.e. the web server in this
' example).

channelNum = ssh.OpenDirectTcpIpChannel("www.chilkatsoft.com",80)
If (channelNum < 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( ssh.LastErrorText) & "</pre>"
    Response.End
End If

' Build a simple HTTP GET request for http://www.chilkatsoft.com/xyz.html
httpReq = "GET /xyz123.html HTTP/1.1" & vbCrLf & "Host: www.chilkatsoft.com" & vbCrLf & vbCrLf

' Send the HTTP request:
success = ssh.ChannelSendString(channelNum,httpReq,"ansi")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ssh.LastErrorText) & "</pre>"
    Response.End
End If

' Get the HTTP response.
' First read the HTTP response header which ends with a double CRLF.
' Calling ChannelReceiveUntilMatch will receive until match string is seen,
' or until a timeout occurs (IdleTimeoutMs property).  ChannelReceiveUntilMatch
' may read beyond the match string, but it will stop reading as soon as the match
' string is seen.
caseSensitive = 0
matchStr = vbCrLf & vbCrLf
success = ssh.ChannelReceiveUntilMatch(channelNum,matchStr,"ansi",caseSensitive)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ssh.LastErrorText) & "</pre>"
    Response.End
End If

' Extract the HTTP header from the receive buffer.
' (GetReceiveTextS extracts up to and including the match string from the receive buffer)

responseHeader = ssh.GetReceivedTextS(channelNum,matchStr,"ansi")
Response.Write "<pre>" & Server.HTMLEncode( "---- HTTP Response Header ----") & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( responseHeader) & "</pre>"

' Now get the body of the HTTP response (this is the HTML content
' of http://www.chilkatsoft.com/xyz.html
' It's possible we've already received the entire HTTP response in the
' call to ChannelReceiveUntilMatch.  Therefore, we'll poll for any remaining data
' and wait a max of .2 seconds.

pollTimeoutMs = 200
numBytesRead = ssh.ChannelPoll(channelNum,pollTimeoutMs)
' We're not checking for an error here.
' A return value of -2 means that no data was available and the poll simply timed out (not an error)
' A return value of -1 indicates an error.
' A return value greater than 0 indicates that additional data was received.

Response.Write "<pre>" & Server.HTMLEncode( "---- HTML BODY ----") & "</pre>"

' Extract the remainder of the accumulated data in the internal receive buffer.
' This should be our HTML body:

htmlBody = ssh.GetReceivedText(channelNum,"ansi")
Response.Write "<pre>" & Server.HTMLEncode( htmlBody) & "</pre>"

' Close the channel:
success = ssh.ChannelSendClose(channelNum)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ssh.LastErrorText) & "</pre>"
    Response.End
End If

' Disconnect
ssh.Disconnect 

%>
</body>
</html>