Classic ASP

Send JSON REST Request, Get JSON Response

Demonstrates sending a RESTful JSON request, and receiving a JSON response. This example will create a bucket in Google Cloud Storage (which involves sending and receiving JSON).

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example will create a bucket in Google Cloud Storage.

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set gAuth = Server.CreateObject("Chilkat.AuthGoogle")
' Obtain an access token as shown in one of the following examples:
' See Get Access Token using a Service Account JSON Key
' See Get Access Token using a P12 File

set rest = Server.CreateObject("Chilkat.Rest")

' Connect using TLS.
bAutoReconnect = 1
success = rest.Connect("www.googleapis.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthGoogle(gAuth)

' Build the JSON request body for creating a bucket.
' The only required property is the "name", but we'll add more
' to make a better example..
set jsonReqBody = Server.CreateObject("Chilkat.JsonObject")
success = jsonReqBody.AppendString("name","chilkat-bucket-c")
success = jsonReqBody.AppendString("kind","storage#bucket")
success = jsonReqBody.AppendString("location","US")

set objVersioning = Server.CreateObject("Chilkat.JsonObject")
success = jsonReqBody.AppendObject2("versioning",objVersioning)
success = objVersioning.AppendBool("enabled",1)

' Show the HTTP request body we'll be sending.
Response.Write "<pre>" & Server.HTMLEncode( jsonReqBody.Emit()) & "</pre>"

' Add the required query parameter.
' See https://cloud.google.com/storage/docs/json_api/v1/buckets/insert
success = rest.AddQueryParam("project","chilkattest-1050")

' Add the Content-Type HTTP request header.
success = rest.AddHeader("Content-Type","application/json; charset=UTF-8")

jsonResponseStr = rest.FullRequestString("POST","/storage/v1/b",jsonReqBody.Emit())
If (rest.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

' Show the JSON response.  (See below for a sample JSON response.)
Response.Write "<pre>" & Server.HTMLEncode( "Json Response: " & jsonResponseStr) & "</pre>"

' {
'  "kind": "storage#bucket",
'  "id": "chilkat-bucket-c",
'  "selfLink": "https://www.googleapis.com/storage/v1/b/chilkat-bucket-c",
'  "projectNumber": "999992999999",
'  "name": "chilkat-bucket-c",
'  "timeCreated": "2016-04-29T21:08:10.451Z",
'  "updated": "2016-04-29T21:08:10.451Z",
'  "metageneration": "1",
'  "owner": {
'   "entity": "project-owners-999992999999"
'  },
'  "location": "US",
'  "versioning": {
'   "enabled": true
'  },
'  "storageClass": "STANDARD",
'  "etag": "CAE="
' }
' 

%>
</body>
</html>