Classic ASP
PKCS11 Find all Public Keys

Demonstrates how to list all public keys on an HSM.
Note: This example requires Chilkat v9.5.0.96 or later.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: Chilkat's PKCS11 implementation runs on Windows, Linux, Mac OS X, and other supported operating systems.

set pkcs11 = Server.CreateObject("Chilkat.Pkcs11")

' Use the PKCS11 driver (.dll, .so, .dylib) for your particular HSM.
' (The format of the path will change with the operating system.  Obviously, "C:/" is not used on non-Windows systems.
pkcs11.SharedLibPath = "C:/Program Files (x86)/Gemalto/IDGo 800 PKCS#11/IDPrimePKCS1164.dll"

' Establish a logged-on session. (We can typically skip the login by passing an empty PIN if only needing to list public keys)
' Use your actual PIN here, or an empty string to skip login.
pin = "0000"
userType = 1
success = pkcs11.QuickSession(userType,pin)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( pkcs11.LastErrorText) & "</pre>"
    Response.End
End If

' Note: To find public keys, we need a session, but it doesn't necessarily need to be logged-on.

set json = Server.CreateObject("Chilkat.JsonObject")
json.EmitCompact = 0

success = pkcs11.FindAllKeys("public",json)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( pkcs11.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( json.Emit()) & "</pre>"

' Sample output, with parsing code below..

' {
'   "keys": [
'     {
'       "handle": 74842125,
'       "id": "0001020304",
'       "key_type": "RSA",
'       "label": "Chilkat Software, Inc.",
'       "modulus": "twVRf6O ... Rwa1ebFY0=",
'       "exponent": "AAEAAQ=="
'     },
'     {
'       "handle": 18415630,
'       "id": "010203040A0B0C0D0E0F",
'       "key_type": "RSA",
'       "label": "ehealth private key",
'       "modulus": "qdKjhOwA1 ... A4MtX8BYgHmLw==",
'       "exponent": "AAEAAQ=="
'     },
'     {
'       "handle": 3735567,
'       "id": "D531B4B8F308489DA58350596178845973A4562E",
'       "key_type": "RSA",
'       "label": "d531b4b8-f308-489d-a583-505961788459",
'       "modulus": "r0MmXRKBP ... HAd1kUPsNyzcQ==",
'       "exponent": "AAEAAQ=="
'     },
'     {
'       "handle": 238092304,
'       "id": "0A0B0C0D01020304",
'       "key_type": "RSA",
'       "label": "MySshKey",
'       "modulus": "ykFHcfBFOq ... rfXBK/6g9t+S6UjJ1kUQ==",
'       "exponent": "AAEAAQ=="
'     },
'     {
'       "handle": 49348625,
'       "id": "48656C6C6F",
'       "key_type": "RSA",
'       "label": "2048-bit RSA key for testing",
'       "modulus": "vReVaJzXZYIOB ... kamD/8iNvhAKlKbQ==",
'       "exponent": "AAEAAQ=="
'     }
'   ]
' }

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

i = 0
count_i = json.SizeOfArray("keys")
Do While i < count_i
    json.I = i
    handle = json.IntOf("keys[i].handle")
    id = json.StringOf("keys[i].id")
    key_type = json.StringOf("keys[i].key_type")
    label = json.StringOf("keys[i].label")
    modulus = json.StringOf("keys[i].modulus")
    exponent = json.StringOf("keys[i].exponent")
    i = i + 1
Loop

success = pkcs11.Logout()
success = pkcs11.CloseSession()

%>
</body>
</html>