Classic ASP
Sign PDF with Invisible Signature

Demonstrates how to sign a PDF with an invisible signature.
Note: This example requires Chilkat v9.5.0.85 or greater.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set pdf = Server.CreateObject("Chilkat.Pdf")

' Load a PDF to be signed.
' The "hello.pdf" is available at https://chilkatsoft.com/hello.pdf
success = pdf.LoadFile("qa_data/pdf/hello.pdf")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( pdf.LastErrorText) & "</pre>"
    Response.End
End If

' Options for signing are specified in JSON.
set json = Server.CreateObject("Chilkat.JsonObject")

' In most cases, the signingCertificateV2 and signingTime attributes are required.
success = json.UpdateInt("signingCertificateV2",1)
success = json.UpdateInt("signingTime",1)

' Indicate that the signature will be invisible.
success = json.UpdateBool("invisibleSignature",1)

' Load the signing certificate. (Use your own certificate.)
set cert = Server.CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("qa_data/pfx/myPdfSigningCert.pfx","secret")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( cert.LastErrorText) & "</pre>"
    Response.End
End If

' Tell the pdf object to use the certificate for signing.
success = pdf.SetSigningCert(cert)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( pdf.LastErrorText) & "</pre>"
    Response.End
End If

success = pdf.SignPdf(json,"qa_output/hello_signed.pdf")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( pdf.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "PDF successfully signed with an invisible signature.") & "</pre>"

' An invisible signature has no appearance within the PDF document itself,
' but Adobe Acrobat will indicate the document is signed in a toolbar, as shown here:
' (image:https://example-code.com/images/invisible_signature.jpg/endImage)

%>
</body>
</html>