Classic ASP

Loading and Parsing a JSON Array

A JSON array is JSON that begins with "[" and ends with "]". For example, this is a JSON array that contains 3 JSON objects.

[{"name":"jack"},{"name":"john"},{"name":"joe"}]

A JSON object, however, is JSON that begins with "{" and ends with "}". For example, this JSON is an object that contains an array.

{"pets":[{"name":"jack"},{"name":"john"},{"name":"joe"}]}

This example shows how loading a JSON array is different than loading a JSON object.

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
strJsonArray = "[{""name"":""jack""},{""name"":""john""},{""name"":""joe""}]"

strJsonObject = "{""pets"":[{""name"":""jack""},{""name"":""john""},{""name"":""joe""}]}"

' A JSON array must be loaded using JsonArray:
set jsonArray = Server.CreateObject("Chilkat.JsonArray")
success = jsonArray.Load(strJsonArray)

' Examine the values:
i = 0
Do While i < jsonArray.Size
    ' jsonObj is a Chilkat.JsonObject
    Set jsonObj = jsonArray.ObjectAt(i)
    Response.Write "<pre>" & Server.HTMLEncode( i & ": " & jsonObj.StringOf("name")) & "</pre>"

    i = i + 1
Loop

' Output is:

' 	0: jack
' 	1: john
' 	2: joe

' A JSON object must be loaded using JsonObject
set jsonObject = Server.CreateObject("Chilkat.JsonObject")
success = jsonObject.Load(strJsonObject)

' Examine the values:
i = 0
numPets = jsonObject.SizeOfArray("pets")
Do While i < numPets
    jsonObject.I = i
    Response.Write "<pre>" & Server.HTMLEncode( i & ": " & jsonObject.StringOf("pets[i].name")) & "</pre>"
    i = i + 1
Loop

' Output is:

' 	0: jack
' 	1: john
' 	2: joe

%>
</body>
</html>