Classic ASP
Download Text File into String Variable

Download a text file directly into a string variable.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ftp = Server.CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.someFtpServer.com"
ftp.Username = "myFtpUserAccount"
ftp.Password = "myFtpPassword"

' Set other possible settings...
' See http://www.cknotes.com/determining-ftp2-connection-settings/ 
' for more information about FTP connection settings.
ftp.Passive = 1
ftp.AuthTls = 1

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If

' Change to the remote directory where the existing file is located.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If

' Download the contents of the remote file into a string variable.

' The GetRemoteFileTextData method assumes the remote file contains ANSI chars.
' To download text files containing non-ANSI text, such as utf-8, call GetRemoteFileTextC
' instead. (see below)
fileContents = ftp.GetRemoteFileTextData("ansiText.txt")
If (ftp.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
Else
    Response.Write "<pre>" & Server.HTMLEncode( fileContents) & "</pre>"
End If

' To download a remote text file containing utf-8 chars, 
' call GetRemoteFileTextC and pass "utf-8" for the 2nd arg.  This tells
' Chilkat to interpret the incoming bytes according to the utf-8 character encoding.

fileContents = ftp.GetRemoteFileTextC("utf8Text.txt","utf-8")
If (ftp.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
Else
    Response.Write "<pre>" & Server.HTMLEncode( fileContents) & "</pre>"
End If

success = ftp.Disconnect()

%>
</body>
</html>