Classic ASP

Get Firebase Access Token from JSON Service Account Private Key

Demonstrates how to get a Firebase access token using a JSON service account private key. Your Firebase service account can be used to authenticate multiple Firebase features, such as Database, Storage and Auth, programmatically.

A Firebase JSON service account private key can be created in the Firebase settings/admin portion of the console.firebase.google.com site as shown here:

Scroll down to see the example code...

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load the Firebase JSON private key into a string.
set fac = Server.CreateObject("Chilkat.FileAccess")
jsonKey = fac.ReadEntireTextFile("qa_data/firebase/firebase-chilkat-firebase-adminsdk-n28n4-1b664ee163.json","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( fac.LastErrorText) & "</pre>"
    Response.End
End If

' A Firebase JSON private key should look something like this:

' { 
'   "type": "service_account",
'   "project_id": "firebase-chilkat",
'   "private_key_id": "1c664ee164907413c91ddefcf5b765ecba8779e2",
'   "private_key": "-----BEGIN PRIVATE KEY-----\nMIIEvQIBA ... Ya2UZii/lXn73/ZOK8=\n-----END PRIVATE KEY-----\n",
'   "client_email": "firebase-adminsdk-n28n4@firebase-chilkat.iam.gserviceaccount.com",
'   "client_id": "134846322329335418431",
'   "auth_uri": "https://accounts.google.com/o/oauth2/auth",
'   "token_uri": "https://accounts.google.com/o/oauth2/token",
'   "auth_provider_x509_cert_url": "https://www.googleapis.com/oauth2/v1/certs",
'   "client_x509_cert_url": "https://www.googleapis.com/robot/v1/metadata/x509/firebase-adminsdk-n28n4%40firebase-chilkat.iam.gserviceaccount.com"
' } 
' 

set gAuth = Server.CreateObject("Chilkat.AuthGoogle")
gAuth.JsonKey = jsonKey

' Choose a scope.
' The scope could be "https://www.googleapis.com/auth/firebase.database"
' or a space-delimited list of scopes:
' "https://www.googleapis.com/auth/firebase.database https://www.googleapis.com/auth/userinfo.email"

gAuth.Scope = "https://www.googleapis.com/auth/firebase.database https://www.googleapis.com/auth/userinfo.email"

' Request an access token that is valid for this many seconds.
gAuth.ExpireNumSeconds = 3600

' If the application is requesting delegated access:
' The email address of the user for which the application is requesting delegated access,
' then set the email address here. (Otherwise leave it empty.)
gAuth.SubEmailAddress = ""

' Connect to www.googleapis.com using TLS (TLS 1.2 is the default.)
' The Chilkat socket object is used so that the connection can be established
' through proxies or an SSH tunnel if desired.
set tlsSock = Server.CreateObject("Chilkat.Socket")
success = tlsSock.Connect("www.googleapis.com",443,1,5000)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( tlsSock.LastErrorText) & "</pre>"
    Response.End
End If

' Send the request to obtain the access token.
success = gAuth.ObtainAccessToken(tlsSock)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( gAuth.LastErrorText) & "</pre>"
    Response.End
End If

' Examine the access token:
Response.Write "<pre>" & Server.HTMLEncode( "Firebase Access Token: " & gAuth.AccessToken) & "</pre>"

' Save the token to a file (or wherever desired).  This token is valid for 1 hour.
success = fac.WriteEntireTextFile("qa_data/tokens/firebaseToken.txt",gAuth.AccessToken,"utf-8",0)

%>
</body>
</html>