Classic ASP
Compress Large Binary File in Blocks

Compresses a large binary file in blocks.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set facSrc = Server.CreateObject("Chilkat.FileAccess")
set facDest = Server.CreateObject("Chilkat.FileAccess")

' Open a large binary file for reading.
success = facSrc.OpenForRead("qa_data/bmp/big.bmp")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( facSrc.LastErrorText) & "</pre>"
    Response.End
End If

' If we compress in 64K chunks, find out how many blocks there will be.
blockSize = 65536
numBlocks = facSrc.GetNumBlocks(blockSize)

' Open an output file for the compressed data.
success = facDest.OpenForWrite("c:/temp/qa_output/compressedBmp.dat")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( facDest.LastErrorText) & "</pre>"
    Response.End
End If

set compress = Server.CreateObject("Chilkat.Compression")
compress.Algorithm = "deflate"

' Assuming numBlocks > 1
compress.FirstChunk = 1
compress.LastChunk = 0

i = 0
Do While i < numBlocks
    fileBytes = facSrc.ReadBlock(i,blockSize)
    compressedBytes = compress.CompressBytes(fileBytes)

    success = facDest.FileWrite(compressedBytes)

    i = i + 1

    compress.FirstChunk = 0
    If (i = (numBlocks - 1)) Then
        compress.LastChunk = 1
    End If

Loop

facSrc.FileClose 
facDest.FileClose 

Response.Write "<pre>" & Server.HTMLEncode( "Finished compressing file.") & "</pre>"

%>
</body>
</html>