Classic ASP
Initiate Resumable Upload Session

Initiate a Google Cloud Storage resumable upload session..
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = Server.CreateObject("Chilkat.Http")

set jsonToken = Server.CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/googleCloudStorage.json")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( jsonToken.LastErrorText) & "</pre>"
    Response.End
End If

set jsonMetaData = Server.CreateObject("Chilkat.JsonObject")
success = jsonMetaData.UpdateString("contentType","image/jpeg")

' Adds the "Authorization: Bearer <access_token>" header..
http.AuthToken = jsonToken.StringOf("access_token")

success = http.SetUrlVar("bucket_name","chilkat-bucket-b")
success = http.SetUrlVar("object_name","penguins2.jpg")
url = "https://storage.googleapis.com/upload/storage/v1/b/{$bucket_name}/o?uploadType=resumable&name={$object_name}"
set resp = Server.CreateObject("Chilkat.HttpResponse")
success = http.HttpJson("POST",url,jsonMetaData,"application/json",resp)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

statusCode = resp.StatusCode
Response.Write "<pre>" & Server.HTMLEncode( "response status code = " & statusCode) & "</pre>"

sessionUrl = ""

If (statusCode <> 200) Then
    Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"
Else
    ' The session URL will be used to upload the file in chunks, in subsequent HTTP POSTs...
    sessionUrl = resp.GetHeaderField("Location")
    Response.Write "<pre>" & Server.HTMLEncode( "Session URL = " & sessionUrl) & "</pre>"
End If


%>
</body>
</html>