Classic ASP
Alabama Motor Fuel Excise Tax E-Filing SOAP XML POST (NewSubmission)

Demonstrates how to post a NewSubmission to the Alabama MFET (Motor Fuel Excise Tax) e-File.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

' Here is an example of an HTTP POST Request we'll be sending:

' POST /WebServices/MFET/ HTTP/1.1
' Content-Type: text/xml
' SOAPAction: NewSubmission
'  
' <soapenv:Envelope
'   xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
'   xmlns:tem="http://tempuri.org/"
'   xmlns:xsd="http://www.w3.org/2001/XMLSchema"
'   xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
'   <soapenv:Header/>
'   <soapenv:Body>
'     <tem:NewSubmission>
'       <tem:UserName>yourusername</tem:UserName>
'       <tem:Password>yourpassword</tem:Password>
'       <tem:File xsi:type="xsd:base64Binary">TRANSMISSION_XML_FILE_CONTENTS_AS_BASE64</tem:File>
'     </tem:NewSubmission>
'   </soapenv:Body>
' </soapenv:Envelope>

' In the above XML, the "TRANSMISSION_XML_FILE_CONTENTS_AS_BASE64" contains the base64 encoded
' string of the XML file that contains "<Transmission> ... </Transmission>"
' First let's load the transmission XML file and get the contents as base64.
set sbXmlFileData = Server.CreateObject("Chilkat.StringBuilder")
success = sbXmlFileData.LoadFile("qa_data/xml/AL_SR_999802_test.xml","utf-8")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Failed to load XML file.") & "</pre>"
    Response.End
End If

success = sbXmlFileData.Encode("base64","utf-8")

' Build the XMl that will be the body of the HTTP request.
set xml = Server.CreateObject("Chilkat.Xml")
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
success = xml.AddAttribute("xmlns:tem","http://tempuri.org/")
success = xml.AddAttribute("xmlns:xsd","http://www.w3.org/2001/XMLSchema")
success = xml.AddAttribute("xmlns:xsi","http://www.w3.org/2001/XMLSchema-instance")
xml.UpdateChildContent "soapenv:Header",""
xml.UpdateChildContent "soapenv:Body|tem:NewSubmission|tem:UserName","yourusername"
xml.UpdateChildContent "soapenv:Body|tem:NewSubmission|tem:Password","yourpassword"
success = xml.UpdateAttrAt("soapenv:Body|tem:NewSubmission|tem:File",1,"xsi:type","xsd:base64Binary")
xml.UpdateChildContent "soapenv:Body|tem:NewSubmission|tem:File",sbXmlFileData.GetAsString()

set http = Server.CreateObject("Chilkat.Http")

http.SetRequestHeader "SoapAction","NewSubmission"

set sbXml = Server.CreateObject("Chilkat.StringBuilder")
success = xml.GetXmlSb(sbXml)

set resp = Server.CreateObject("Chilkat.HttpResponse")
success = http.HttpSb("POST","https://mattest.alabama.gov/WebServices/MFET/",sbXml,"utf-8","text/xml",resp)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "Response status code = " & resp.StatusCode) & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( "Response body text:") & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"

' The response will look like this:

' <?xml version="1.0" encoding="utf-8" ?>
' <s:Envelope xmlns:s="http://schemas.xmlsoap.org/soap/envelope/">
'     <s:Body>
'         <NewSubmissionResponse xmlns="http://tempuri.org/">
'             <NewSubmissionResult i:type="a:base64Binary" xmlns:a="http://www.w3.org/2001/XMLSchema" xmlns:i="http://www.w3.org/2001/XMLSchema-instance">BASE64_RESULT</NewSubmissionResult>
'         </NewSubmissionResponse>
'     </s:Body>
' </s:Envelope>

' We can get the base64 result like this:
set xmlResult = Server.CreateObject("Chilkat.Xml")
success = xmlResult.LoadXml(resp.BodyStr)
set sbResult = Server.CreateObject("Chilkat.StringBuilder")
success = sbResult.Append(xmlResult.GetChildContent("s:Body|NewSubmissionResponse|NewSubmissionResult"))
success = sbResult.Decode("base64","utf-8")
Response.Write "<pre>" & Server.HTMLEncode( "Decoded result:") & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( sbResult.GetAsString()) & "</pre>"

' A sample of a decoded error response:

' <?xml version="1.0" encoding="utf-8"?>
' <!--ADOR Acknowledgement 1-->
' <Transmission xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://www.irs.gov/efile">
'   <Jurisdiction>ALABAMA</Jurisdiction>
'   <TransmissionId>2018-09-1019:14R000000001</TransmissionId>
'   <Timestamp>2018-09-10T19:14:12Z</Timestamp>
'   <Transmitter>
'     <ETIN>00000</ETIN>
'   </Transmitter>
'   <ProcessType>P</ProcessType>
'   <AgentIdentifier>ACK</AgentIdentifier>
'   <AcknowledgementID>0</AcknowledgementID>
'   <AcknowledgementTimeStamp>2018-09-11T21:16:34-05:00</AcknowledgementTimeStamp>
'   <Errors>
'     <Error>Process Type must be 'T' when submitted to Testing Web Service</Error>
'   </Errors>
' </Transmission>

%>
</body>
</html>