Classic ASP
AES Encrypt String (utf-8 byte representation) and return Base64

Demonstrates how to AES encrypt the utf-8 byte representation of a string and return in base64 format.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = Server.CreateObject("Chilkat.Crypt2")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 256
crypt.Charset = "utf-8"
crypt.EncodingMode = "base64"

ivHex = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedIV ivHex,"hex"
keyHex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey keyHex,"hex"

encryptedStr = crypt.EncryptStringENC("This is the original string")
Response.Write "<pre>" & Server.HTMLEncode( encryptedStr) & "</pre>"

' Let's say we want to URL encode the base64 string..
crypt.CryptAlgorithm = "none"
crypt.EncodingMode = "url"
urlEncoded = crypt.EncryptStringENC(encryptedStr)
Response.Write "<pre>" & Server.HTMLEncode( urlEncoded) & "</pre>"

' Sample output:

'  q3fmgEqjqa9o//ZS6aPuh4Wtbrrxx/WOIQSKeVnesZg=
'  q3fmgEqjqa9o%2F%2FZS6aPuh4Wtbrrxx%2FWOIQSKeVnesZg%3D

' -------------------------------------------------------------------
' Now let's do the reverse...
' 

' We start with a string that is the binary encrypted data, base64 encoded, and then URL encoded.
encBase64Url = "q3fmgEqjqa9o%2F%2FZS6aPuh4Wtbrrxx%2FWOIQSKeVnesZg%3D"

' We'll use the same crypt object.  If using a new instance of the crypt object,
' make sure *all* settings are identical:  the algorithm, cipher mode, key length, charset, encoding mode, IV, and secret key.

' Decode from URL...
crypt.CryptAlgorithm = "none"
crypt.EncodingMode = "url"
encBase64 = crypt.DecryptStringENC(urlEncoded)
Response.Write "<pre>" & Server.HTMLEncode( encBase64) & "</pre>"

' Now decrypt...
crypt.CryptAlgorithm = "aes"
crypt.EncodingMode = "base64"
originalStr = crypt.DecryptStringENC(encBase64)
Response.Write "<pre>" & Server.HTMLEncode( originalStr) & "</pre>"

%>
</body>
</html>