Xojo Plugin

Starting an Asynchronous Task

Chilkat methods that have a name ending in "Async" return a task object. The task object can be run asynchronously on Chilkat's background thread pool. The purpose of this example is to demonstrate how a Task is started via the Run method. It also demonstrates how an application can check on the status of the task, and get the task return value. See the online reference documentation for the full details of the task and task chain objects. Also see the "Task" category on example-code.com for more examples. Xojo Plugin

Dim success As Boolean
success = False

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

success = False

Dim mailman As New Chilkat.MailMan

// Set the SMTP server and any required settings.
mailman.SmtpHost = "smtp.mymailserver.com"
mailman.SmtpUsername = "myLogin"
mailman.SmtpPassword = "myPassword"
mailman.StartTLS = True

// Create a new email object
Dim email As New Chilkat.Email

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
success = email.AddTo("Chilkat Admin","admin@chilkatsoft.com")

// Call the async version of the SendEmail method to return a task object.
// The task object is loaded, but is in the Inert state -- meaning it is
// not yet scheduled to run on Chilkat's background thread pool.
Dim task As Chilkat.Task
task = mailman.SendEmailAsync(email)
If (mailman.LastMethodSuccess = False) Then
    System.DebugLog(mailman.LastErrorText)
    Return
End If

// Schedule the task for running on the thread pool.  This changes the task's state
// from Inert to Live.
success = task.Run()
If (success <> True) Then
    System.DebugLog(task.LastErrorText)

    Return
End If

// The application is now free to do anything else
// while the email is being sent.

// For this example, we'll simply sleep and periodically
// check to see if the SendEmail if finished.  While checking
// however, we'll report on the progress.
Dim curPctDone As Int32
curPctDone = 0
While task.Finished <> True

    If (task.PercentDone <> curPctDone) Then
        curPctDone = task.PercentDone
        System.DebugLog(Str(curPctDone) + " percent done")
    End If

    // Sleep 100 ms.
    task.SleepMs 100

Wend

// A finished task could be one that was canceled, aborted, or truly finished.  

// If the task was "canceled", it was canceled prior to actually starting.  This could
// happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
// background thread pool scheduler.  

// If the task was "aborted", it indicates that it was canceled while running in a background thread.  
// The ResultErrorText will likely indicate that the task was aborted.

// If the task "completed", then it ran to completion, but the actual success/failure of the method
// is determined by the result obtained via a GetResult* method.  (A "completed" task will
// have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
// been aborted or canceled:
If (task.StatusInt <> 7) Then
    System.DebugLog("Task did not complete.")
    System.DebugLog("task status: " + task.Status)

    Return
End If

// The SendEmail method returns a boolean.  Therefore, after the task is finished,
// we can get the boolean result by calling GetResultBool.  This is the return value had
// we called SendEmail synchronously.
success = task.GetResultBool()
If (success <> True) Then
    // The task's ResultErrorText contains what would have been in the LastErrorText property had
    // the SendEmail method been called synchronously.
    System.DebugLog(task.ResultErrorText)
Else
    System.DebugLog("Email sent asynchronously.")
End If

success = mailman.CloseSmtpConnection()
If (success <> True) Then
    System.DebugLog("Connection to SMTP server not closed cleanly.")

End If