Modify Name of File Stored within Zip when Creating a .zip

Demonstrates how to create a zip where the filename within the .zip is different than the filename that was added from the filesystem.

Download Chilkat Zip ActiveX

set zip = CreateObject("Chilkat.Zip2")

success = zip.UnlockComponent("anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock zip component"
    WScript.Quit
End If

'  Intialize the zip object by calling NewZip.
zip.NewZip "myZip.zip"

'  Add a reference to a file on disk to the zip object.
'  (When appending files to a zip, the files are not actually
'  read into memory.  References to the file(s) are added.
'  When WriteZip is called, the referenced files are streamed in
'  and compressed to the .zip.)
saveExtraPath = 0
success = zip.AppendOneFileOrDir("c:/temp/a/hamlet.xml",saveExtraPath)
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

'  The zip object references a single file.
'  Retrieve the entry object...

Set entry = zip.GetEntryByIndex(0)

'  Set the entry's filename to anything you want:
entry.FileName = "somethingElse.xml"

'  Note: Internally, the zip component retains the name of
'  the file referenced.  The current setting of the zip entry's
'  FileName property is stored in the .zip when writing.

'  The zip written here will contain somethingElse.xml
success = zip.WriteZipAndClose()
If (success <> 1) Then
    MsgBox zip.LastErrorText
Else
    MsgBox "Zip created!"
End If