Self-Extract EXE to Temp and Auto-Run Setup Program

Download Chilkat 32-bit Zip ActiveX (.msi) (includes objects for .zip, .gz, .bz2, and .Z)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

How to create a self-extracting EXE that extracts to a temp directory and auto-runs a setup program after extracting.

set zip = CreateObject("Chilkat.Zip2")

'  Any string unlocks the component for the 1st 30-days.
success = zip.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

'  Initialize the zip object.  Because we're creating
'  a self-extracting EXE in this example, the filename
'  passed to NewZip will never actually be created.
success = zip.NewZip("notUsed.zip")
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

'  Append a directory tree.  The AppendFiles does
'  not read the file contents or append them to the zip
'  object in memory.  It simply appends references
'  to the files so that when WriteExe (or WriteZipAndClose,
'  or WriteZip, etc.) is called, the files are compressed
'  and added to the archive.
recurse = 1
zip.AppendFiles "c:/temp/a/*",recurse

'  Indicate that when the EXE is run, it should automatically
'  extract to a temp directory.
zip.AutoTemp = 1

'  If you want the EXE to self-extract with no user-interface,
'  add this:
zip.ExeNoInterface = 1
zip.ExeSilentProgress = 1
zip.ExeWaitForSetup = 0

'  Indicate that after extracting, a setup program should be run:
zip.AutoRun = "setup.exe"

'  Pass these command line params to the AutoRun program:
zip.AutoRunParams = "-a -b -c"

'  Write "mySfx.exe"
success = zip.WriteExe("mySfx.exe")
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

MsgBox "EXE Created!"