Encrypt XML Subtree

Encrypt an entire subtree within an XML document

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)


set xml = CreateObject("Chilkat.Xml")

'  First, build a sample XML document:

set xml = CreateObject("Chilkat.Xml")

xml.Tag = "stocks"

Set xmlM = xml.NewChild("Microsoft","")
xmlM.NewChild2 "symbol","MSFT"
xmlM.NewChild2 "recentPrice","34.50"

Set xmlG = xml.NewChild("Google","")
xmlG.NewChild2 "symbol","GOOG"
xmlG.NewChild2 "recentPrice","679.00"

'  Display the unencrypted XML:
outFile.WriteLine(xml.GetXml())

'  This is the XML displayed:
'  <stocks>
'      <Microsoft>
'          <symbol>MSFT</symbol>
'          <recentPrice>34.50</recentPrice>
'      </Microsoft>
'      <Google>
'          <symbol>GOOG</symbol>
'          <recentPrice>679.00</recentPrice>
'      </Google>
'  </stocks>

'  The goal is to encrypt the "Microsoft" sub-tree.
'  The EncryptContent method encryptes the content
'  within a single XML node (not an entire sub-tree).
'  Therefore, to encrypt a sub-tree,  you must first
'  compress it into a single node, and then encrypt it.
xmlM.ZipTree 

'  Now encrypt the content using 128-bit AES encryption:
xmlM.EncryptContent "secretPassword"

'  Display the XML with the encrypted sub-tree:
outFile.WriteLine(xml.GetXml())

'  This is displayed:
'  <stocks>
'      <Microsoft><![CDATA
'  [JkiMcoK3Mi198rT30KvicDEzu5WuJgMH+8KS0UZbcRE
'  2CtdXplphV0iCdPMYnS01O6Ly6S4QCQSReMCshG/V3
'  8btJIZv/VLG9JZRsQk0bBafMhx7B2fQfm8YENke/JIM
'  ]]>    </Microsoft>
'      <Google>
'          <symbol>GOOG</symbol>
'          <recentPrice>679.00</recentPrice>
'      </Google>
'  </stocks>

'  Now decrypt and unzip:
xmlM.DecryptContent "secretPassword"

success = xmlM.UnzipTree()
If (success <> 1) Then
    outFile.WriteLine("Failed to unzip tree")
End If

'  Display the restored document:
outFile.WriteLine(xml.GetXml())


outFile.Close