Add Child Tree

Add a child tree to an existing XML document.

Download Chilkat XML ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)


'  First, build a sample XML document:
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "stocks"

Set xmlM = xml.NewChild("Microsoft","")
xmlM.NewChild2 "symbol","MSFT"
xmlM.NewChild2 "recentPrice","28.00"

Set xmlG = xml.NewChild("Google","")
xmlG.NewChild2 "symbol","GOOG"
xmlG.NewChild2 "recentPrice","440.00"

'  Display the XML so far...
outFile.WriteLine(xml.GetXml())

'  This is the XML displayed:
'  <stocks>
'      <Microsoft>
'          <symbol>MSFT</symbol>
'          <recentPrice>28.00</recentPrice>
'      </Microsoft>
'      <Google>
'          <symbol>GOOG</symbol>
'          <recentPrice>440.00</recentPrice>
'      </Google>
'  </stocks>

'  We want to add Yahoo to it:

xYahoo = "<Yahoo><symbol>YHOO</symbol><recentPrice>28.00</recentPrice></Yahoo>"

set xmlYahoo = CreateObject("Chilkat.Xml")
xmlYahoo.LoadXml xYahoo

'  Add the xmlYahoo document just under the root node of
'  our original XML document:
xml.AddChildTree xmlYahoo

'  Display the result:
outFile.WriteLine(xml.GetXml())


outFile.Close