Demonstrates the ChilkatPath XML Method

Demonstrates how to use the ChilkatPath method. This example uses the XML sample file pigs.xml. The pigs.xml file contains this content:

Download Chilkat XML ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set xml = CreateObject("Chilkat.Xml")

success = xml.LoadXmlFile("pigs.xml")
If (success <> 1) Then
    MsgBox xml.LastErrorText
    WScript.Quit
End If

'  Get the content of the "species" node for the 1st animal:

result = xml.ChilkatPath("animal|species|*")
'  Output should be "pot belly pig"
outFile.WriteLine(result)

'  Get the content of the "type" node for the 2nd animal:
'  Indexing begins at 0.  Therefore, the 2nd direct child having
'  the tag "animal" is at index 1
result = xml.ChilkatPath("animal[1]|type|*")
'  Output should be "House Pig"
outFile.WriteLine(result)

'  Find the pig having the name "Nigel" and display the
'  birth date.  To do this, we'll navigate to the node having
'  tag="name" with the exact content "Nigel", then navigate up,
'  and finally navigate back down to the "birth" node:
result = xml.ChilkatPath("/C/name,Nigel|..|birth|*")
'  Output should be "June, 1991"
outFile.WriteLine(result)

'  Navigate to the 1st animal's picture and print the filename,
'  description, and caption.
'  The "$" updates the caller's internal pointer to reference
'  the node that is the result of evaluating the path.
'  An empty string is returned for success, and a NULL/nil/0
'  pointer (reference) is returned on failure.
result = xml.ChilkatPath("animal|picture|$")
If (result = vbNullString ) Then
    outFile.WriteLine("Failed to navigate to animal|picture.")
    WScript.Quit
End If

'  Display the contents of the file/description/caption child nodes
outFile.WriteLine("Picture Info:")
outFile.WriteLine(xml.GetChildContent("file"))
outFile.WriteLine(xml.GetChildContent("description"))
outFile.WriteLine(xml.GetChildContent("caption"))

'  Return back to the root of the XML document:
xml.GetRoot2 

'  Display the value of the "spay-neuter" attribute of the 1st animal:
outFile.WriteLine("----")
result = xml.ChilkatPath("animal|gender|(spay-neuter)")
outFile.WriteLine(result)


outFile.Close