Unzip Encrypted Text into a String Variable

Demonstrates how to open an encrypted .zip archive and unzip a text file directly into a string variable.

Download Chilkat 32-bit Zip ActiveX (.msi) (includes objects for .zip, .gz, .bz2, and .Z)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set zip = CreateObject("Chilkat.Zip2")

'  Any string unlocks the component for the 1st 30-days.
success = zip.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

'  Set the password required for decrypting.
zip.DecryptPassword = "myPassword"

success = zip.OpenZip("encrypted.zip")
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

'  Locate the file within the Zip to be unzipped into a string variable:

' entry is a Chilkat.ZipEntry2
Set entry = zip.FirstMatchingEntry("*.csv")
If (Not (entry Is Nothing )) Then

    '  There are a few different InflateToString methods.
    '  InflateToString allows you to control line-endings LF-only vs. CRLF
    '  InflateToString2 returns the line-endings unmodified.
    '  Both InflateToString and InflateToString2 assume the
    '  data consists of ANSI characters.
    '  The InflateToString3 method allows for text stored in different
    '  character encodings to be returned as a string

    '  This example uses InflateToString2 -- line endings are
    '  unmodified and the text is simple ANSI...

    strCsv = entry.InflateToString2()
    outFile.WriteLine(strCsv)

Else
    outFile.WriteLine("No matching entry found!")
End If


outFile.Close