The Chilkat StringArray object

The Chilkat string array object is a utility class used by many of the Chilkat components. It's not an array. It's an object that contains 0 or more strings that can be retrieved by index. The reason Chilkat created this object is that string arrays are handled differently in different programming languages. The CkStringArray object (or Chilkat.StringArray in .NET) is used whenever a collection of strings is passed to a method, or returned from a method. This example demonstrates some very basic usage. How to create a string array, populate it with some entries, sort it, retrieve entries, etc.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  This is not an array -- it's an object.
set sa = CreateObject("Chilkat.CkStringArray")

'  Append some strings.
sa.Append "abc"
sa.Append "Abc"
sa.Append "123"
sa.Append "Chilkat Software, Inc."

'  How many strings?

n = sa.Count
outFile.WriteLine(n)

'  Iterate over the strings contained in the object:

For i = 0 To n - 1
    outFile.WriteLine(sa.GetString(i))
Next

'  Sort in ascending order:

ascending = 1
sa.Sort ascending

outFile.WriteLine("Sorted:")
For i = 0 To n - 1
    outFile.WriteLine(sa.GetString(i))
Next

'  Save to a file (one string per line).
'  Line endings are controlled by the Crlf property.
useCrlf = 1
sa.Crlf = useCrlf
sa.SaveToFile "strings.txt"

'  Clear the string array.
sa.Clear 

'  Load the string array from a file.  Each line in the
'  file becomes a string contained in the object:
sa.LoadFromFile "strings.txt"

'  Remove a string by exact match:
sa.Remove "abc"

'  Remove a string by index (1st string is at index 0):
sa.RemoveAt 2

'  The Trim property can be set to automatically trim whitespace
'  from the beginning and end of any string added to the object:
sa.Trim = 1

'  Append some strings from a comma-separated list:
sa.SplitAndAppend "apple, orange, banana, pear, lime",","

'  What do we have now?
outFile.WriteLine("-------- After SplitAndAppend:")
n = sa.Count
For i = 0 To n - 1
    outFile.WriteLine(sa.GetString(i))
Next

'  Serialize the complete object to a base64 string:

serialized = sa.Serialize()

outFile.WriteLine("-------- Serialized:")
outFile.WriteLine(serialized)

'  Restore from a serialized string:
set sa2 = CreateObject("Chilkat.CkStringArray")
sa2.AppendSerialized serialized

outFile.WriteLine("-------- After AppendSerialized:")
n = sa2.Count
For i = 0 To n - 1
    outFile.WriteLine(sa2.GetString(i))
Next

'  Set the Unique property to prevent duplicates from being added:
sa.Unique = 1
sa.Clear 
sa.Append "apple"
sa.Append "banana"
sa.Append "apple"
sa.Append "banana"

'  What do we have now?
outFile.WriteLine("-------- Unique strings:")
n = sa.Count
For i = 0 To n - 1
    outFile.WriteLine(sa.GetString(i))
Next

'  Find the location of a specific string
'  (case insensitive).

startIndex = 0
index = sa.Find("apple",startIndex)
If (index >= 0) Then
    outFile.WriteLine("found apple at index " _
         & index)
Else
    outFile.WriteLine("apple not found")
End If

outFile.Close