SSL Server Example

Demonstrates how to create an SSL socket for accepting connections. This example is *very* simple in that it will create an SSL socket for accepting a single connection. It will read a message from the client, send a reply, and exit.

Download Chilkat Socket ActiveX

set listenSslSocket = CreateObject("Chilkat.Socket")

'  Any string automatically begins a fully-functional 30-day trial.

success = listenSslSocket.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock component"
    WScript.Quit
End If

'  An SSL server needs a digital certificate.  This example loads it from a PFX file.

'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it.
'  (a PFX file may contain more than one certificate.)
set certStore = CreateObject("Chilkat.CertStore")
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = certStore.LoadPfxFile("chilkat.pfx","test")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

'  Find the certificate to be used for SSL:

' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

'  Use the certificate:
success = listenSslSocket.InitSslServer(cert)
If (success <> 1) Then
    MsgBox listenSslSocket.LastErrorText
    WScript.Quit
End If

'  Bind and listen on a port:
myPort = 8123
'  Allow for a max of 5 queued connect requests.
backLog = 5
success = listenSslSocket.BindAndListen(myPort,backLog)
If (success <> 1) Then
    MsgBox listenSslSocket.LastErrorText
    WScript.Quit
End If

'  If accepting an SSL/TLS connection, the SSL handshake is part of the connection
'  establishment process. This involves a few back-and-forth messages between the
'  client and server to establish algorithms and a shared key to create the secure
'  channel. The sending and receiving of these messages are governed by the
'  MaxReadIdleMs and MaxSendIdleMs properties. If these properties are set to 0
'  (and this is the default unless changed by your application), then the
'  AcceptNextConnection can hang indefinitely during the SSL handshake process.
'  Make sure these properties are set to appropriate values before calling AcceptNextConnection.

'  Set a 10 second max for waiting to read/write.  This is for the SSL/TLS handshake establishment.
listenSslSocket.MaxReadIdleMs = 10000
listenSslSocket.MaxSendIdleMs = 10000

'  Accept a single client connection and establish the secure SSL/TLS channel:

maxWaitMillisec = 20000
' clientSock is a Chilkat.Socket
Set clientSock = listenSslSocket.AcceptNextConnection(maxWaitMillisec)
If (clientSock Is Nothing ) Then
    MsgBox listenSslSocket.LastErrorText
    WScript.Quit
End If

'  The client (in this example) is going to send a "Hello Server! -EOM-"
'  message.  Read it:

receivedMsg = clientSock.ReceiveUntilMatch("-EOM-")
If (receivedMsg = vbNullString ) Then
    MsgBox clientSock.LastErrorText
    WScript.Quit
End If

MsgBox receivedMsg

'  Send a "Hello Client! -EOM-" message:
success = clientSock.SendString("Hello Client! -EOM-")
If (success <> 1) Then
    MsgBox clientSock.LastErrorText
    WScript.Quit
End If

'  Close the connection with the client
'  Wait a max of 20 seconds (20000 millsec)
clientSock.Close 20000