Asynchronous SSL Client Example

Demonstrates how to connect to an SSL server, send a simple message, receive a simple response, and disconnect. This example uses the asynchronous methods to connect, send, and receive.

Download Chilkat Socket ActiveX

set socket = CreateObject("Chilkat.Socket")

success = socket.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock component"
    WScript.Quit
End If

ssl = 1
maxWaitMillisec = 20000

'  The SSL server hostname may be an IP address, a domain name,
'  or "localhost".  You'll need to change this:

sslServerHost = "123.123.88.88"
sslServerPort = 8123

'  Connect to the SSL server asynchronously in a background thread.
success = socket.AsyncConnectStart(sslServerHost,sslServerPort,ssl,maxWaitMillisec)
If (success <> 1) Then
    MsgBox socket.LastErrorText
    WScript.Quit
End If

'  Wait for the socket to become connected...
Do While (socket.AsyncConnectFinished <> 1)
    '  Sleep 1 second.
    socket.SleepMs 1000
Loop

'  Did the connect fail?
If (socket.AsyncConnectSuccess <> 1) Then
    MsgBox socket.AsyncConnectLog
    WScript.Quit
End If

'  Set maximum timeouts for reading an writing (in millisec)
socket.MaxReadIdleMs = 20000
socket.MaxSendIdleMs = 20000

'  Send a "Hello Server! -EOM-" message:
success = socket.AsyncSendString("Hello Server! -EOM-")
If (success <> 1) Then
    MsgBox socket.LastErrorText
    WScript.Quit
End If

'  Wait for the send to finish
Do While (socket.AsyncSendFinished <> 1)
    '  Sleep 1 second.
    socket.SleepMs 1000
Loop

'  Did the send fail?
If (socket.AsyncSendSuccess <> 1) Then
    MsgBox socket.AsyncSendLog
    WScript.Quit
End If

'  The server (in this example) is going to send a "Hello Client! -EOM-"
'  message.  Begin reading asynchronously in a background thread:
success = socket.AsyncReceiveUntilMatch("-EOM-")
If (success <> 1) Then
    MsgBox socket.LastErrorText
    WScript.Quit
End If

'  Wait for the background read to finish
Do While (socket.AsyncReceiveFinished <> 1)
    '  Sleep 1 second.
    socket.SleepMs 1000
Loop

'  Did the receive fail?
If (socket.AsyncReceiveSuccess <> 1) Then
    MsgBox socket.AsyncReceiveLog
    WScript.Quit
End If

'  Display the received message:
MsgBox socket.AsyncReceivedString

'  Close the connection with the server
'  Wait a max of 20 seconds (20000 millsec)
socket.Close 20000