SSH -- Running Commands that Prompt for Additional Input, such as "su"

Demonstrates how to run a shell command via SSH where the shell command prompts for additional input from the client. This example demonstrates "su".

Download Chilkat 32-bit SSH / SFTP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  Important: It is helpful to send the contents of the
'  ssh.LastErrorText property when requesting support.

set ssh = CreateObject("Chilkat.Ssh")

'  Any string automatically begins a fully-functional 30-day trial.
success = ssh.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Hostname may be an IP address or hostname:
hostname = "192.168.1.117"
port = 22

'  Keep a session log, which is available via the SessionLog
'  property:
ssh.KeepSessionLog = 1

success = ssh.Connect(hostname,port)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  When reading, if no additional data arrives for more than
'  5 seconds, then abort:
ssh.IdleTimeoutMs = 5000

'  SSH Server Authentication
'  If there is no login/password required, you must still call
'  AuthenticatePw and use any values for login/password.
success = ssh.AuthenticatePw("chilkat","myPassword")
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Open a session channel.

channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Request a pseudo-terminal
termType = "dumb"
widthInChars = 120
heightInChars = 40
pixWidth = 0
pixHeight = 0
success = ssh.SendReqPty(channelNum,termType,widthInChars,heightInChars,pixWidth,pixHeight)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Start a shell on the channel:
success = ssh.SendReqShell(channelNum)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Send the su command.
'  (The SSH server I'm using for testing is a Linux Ubuntu
'  system running OpenSSH.  It is important in this case to send a bare-LF
'  and not a CRLF.)

cmd = "su" & vbLf
success = ssh.ChannelSendString(channelNum,cmd,"ansi")
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Read until we get the prompt for the password:
success = ssh.ChannelReceiveUntilMatch(channelNum,"Password:","ansi",1)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Display what we've received so far:
outFile.WriteLine(ssh.GetReceivedText(channelNum,"ansi"))

'  Send the password.
'  Again, make sure it uses a bare-LF and not a CRLF.

password = "myPassword" & vbLf
success = ssh.ChannelSendString(channelNum,password,"ansi")
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Read the response until we get the shell prompt (assuming it's successful)
'  In my case, the shell prompt is: "root@ubuntu:/home/chilkat# "
'  It will be different in your case.
success = ssh.ChannelReceiveUntilMatch(channelNum,"root@ubuntu:/home/chilkat#","ansi",1)
If (success <> 1) Then
    '  Check the last-error information and the session log...
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    '  Check to see what was received.
    outFile.WriteLine(ssh.GetReceivedText(channelNum,"ansi"))
    WScript.Quit
End If

'  Display what we've received so far.  This clears
'  the internal receive buffer, which is important.
'  After we send the command, we'll be reading until
'  the next command prompt.  If the command prompt
'  is already in the internal receive buffer, we'll think we're
'  already finished...
outFile.WriteLine(ssh.GetReceivedText(channelNum,"ansi"))

'  Send a command.  In this case, we are sending the "ls" command:
cmd = "ls" & vbLf
success = ssh.ChannelSendString(channelNum,cmd,"ansi")
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Read until the next command prompt:
success = ssh.ChannelReceiveUntilMatch(channelNum,"root@ubuntu:/home/chilkat#","ansi",1)
If (success <> 1) Then
    '  Check the last-error information and the session log...
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    '  Check to see what was received.
    outFile.WriteLine(ssh.GetReceivedText(channelNum,"ansi"))
    WScript.Quit
End If

'  Display the command output:
outFile.WriteLine(ssh.GetReceivedText(channelNum,"ansi"))

'  You may continue sending additional commands.
'  The technique is: send the command, read until the next command prompt,
'  and then fetch/clear the internal receive buffer.

'  We're done, so shut it down..

'  Send an EOF.  This tells the server that no more data will
'  be sent on this channel.  The channel remains open, and
'  the SSH client may still receive output on this channel.
success = ssh.ChannelSendEof(channelNum)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Close the channel:
success = ssh.ChannelSendClose(channelNum)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    outFile.WriteLine(ssh.SessionLog)
    WScript.Quit
End If

'  Disconnect
ssh.Disconnect 
outFile.Close