Multiple SendReqExec on Same Connection

Shows how to execute a series of commands on an SSH server and retrieve each command's output (using SendReqExec). Each call to SendReqExec requires its own logical session channel. This is not a separate TCP/IP connection -- it's simply a new session channel on the existing connection. The sequence of Chilkat SSH calls would look like this:

Connect
AuthenticatePw (or AuthenticatePk)

OpenSessionChannel
SendReqExec
<retrieve command output...>
SendChannelClose
ChannelReceiveToClose (to make sure all remaining output is received)

OpenSessionChannel
SendReqExec
<retrieve command output...>
SendChannelClose
ChannelReceiveToClose (to make sure all remaining output is received)

...

OpenSessionChannel
SendReqExec
<retrieve command output...>
SendChannelClose
ChannelReceiveToClose (to make sure all remaining output is received)

Disconnect

Download Chilkat 32-bit SSH / SFTP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  Important: It is helpful to send the contents of the
'  ssh.LastErrorText property when requesting support.

set ssh = CreateObject("Chilkat.Ssh")

'  Any string automatically begins a fully-functional 30-day trial.
success = ssh.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Connect to an SSH server:

'  Hostname may be an IP address or hostname:
hostname = "192.168.1.108"
port = 22

success = ssh.Connect(hostname,port)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Wait a max of 5 seconds when reading responses..
ssh.IdleTimeoutMs = 5000

'  Authenticate using login/password:
success = ssh.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Open a session channel.  (It is possible to have multiple
'  session channels open simultaneously.)

channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Request a directory listing on the remote server:
'  If your server is Linux/UNIX, change the string from "dir" to "ls"
'  Note: Some SSH servers require a CRLF instead of a bare-LF

cmd = "ls -al" & lf
success = ssh.SendReqExec(channelNum,cmd)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Read whatever output may already be available on the
'  SSH connection.  ChannelReadAndPoll returns the number of bytes
'  that are available in the channel's internal buffer that
'  are ready to be "picked up" by calling GetReceivedText
'  or GetReceivedData.
'  A return value of -1 indicates failure.
'  A return value of -2 indicates a failure via timeout.

'  The ChannelReadAndPoll method waits
'  for data to arrive on the connection usingi the IdleTimeoutMs
'  property setting.  Once the first data arrives, it continues
'  reading but instead uses the pollTimeoutMs passed in the 2nd argument:
'  A return value of -2 indicates a timeout where no data is received.

pollTimeoutMs = 2000
n = ssh.ChannelReadAndPoll(channelNum,pollTimeoutMs)
If (n < 0) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Close the channel:
success = ssh.ChannelSendClose(channelNum)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Perhaps we did not receive all of the commands output.
'  To make sure,  call ChannelReceiveToClose to accumulate any remaining
'  output until the server's corresponding "channel close" is received.
success = ssh.ChannelReceiveToClose(channelNum)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Let's pickup the accumulated output of the command:

cmdOutput = ssh.GetReceivedText(channelNum,"ansi")
If (cmdOutput = vbNullString ) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Display the remote shell's command output:
outFile.WriteLine(cmdOutput)
outFile.WriteLine("----")

'  -----------------------------------------------------------------
'  Now for the 2nd SendReqExe (on the same connection,
'  but on a separate logical channel).
'  -----------------------------------------------------------------

channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

cmd = "nslookup chilkatsoft.com" & lf
success = ssh.SendReqExec(channelNum,cmd)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

pollTimeoutMs = 2000
n = ssh.ChannelReadAndPoll(channelNum,pollTimeoutMs)
If (n < 0) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

success = ssh.ChannelSendClose(channelNum)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

success = ssh.ChannelReceiveToClose(channelNum)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

cmdOutput = ssh.GetReceivedText(channelNum,"ansi")
If (cmdOutput = vbNullString ) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

outFile.WriteLine(cmdOutput)

'  Disconnect
ssh.Disconnect 
outFile.Close