Make a Copy of a File on Remote SSH Server

Demonstrates how to make a copy of a file on a remote SSH server by running the "cp" command. This works if your server is Linux or Unix-based. For Windows-based servers, use the DOS "copy" command.

Download Chilkat 32-bit SSH / SFTP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  Important: It is helpful to send the contents of the
'  ssh.LastErrorText property when requesting support.

set ssh = CreateObject("Chilkat.Ssh")

'  Any string automatically begins a fully-functional 30-day trial.
success = ssh.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Connect to an SSH server:

'  Hostname may be an IP address or hostname:
hostname = "192.168.1.117"
port = 22

success = ssh.Connect(hostname,port)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Wait a max of 5 seconds when reading responses..
ssh.IdleTimeoutMs = 5000

'  Authenticate using login/password:
success = ssh.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Open a session channel.  (It is possible to have multiple
'  session channels open simultaneously.)

channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  In this example, we'll copy wine.html to wine2.html
'  The "cp" command has no output (i.e. nothing is written to
'  the standard output) so we'll include an "echo FINISHED"
'  so we can programmatically retrieve the output and close
'  the channel.  Closing the channel immediately after sending
'  the command is not good because w/ some SSH servers
'  it introduces a race condition where the command may not
'  be executed if the server thinks the client has disconnected.
success = ssh.SendReqExec(channelNum,"cp wine.html wine2.html && echo FINISHED")
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Read the channel until we receive the FINISHED string.
success = ssh.ChannelReceiveUntilMatch(channelNum,"FINISHED","ansi",1)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Close the channel:
success = ssh.ChannelSendClose(channelNum)
If (success <> 1) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Let's pickup the accumulated output of the command:
'  (In this case, it will be the string "FINISHED")

cmdOutput = ssh.GetReceivedText(channelNum,"ansi")
If (cmdOutput = vbNullString ) Then
    MsgBox ssh.LastErrorText
    WScript.Quit
End If

'  Display the remote shell's command output:
outFile.WriteLine(cmdOutput)

'  Disconnect
ssh.Disconnect 
outFile.Close