Avoid URLs Matching Any of a Set of Patterns

Demonstrates how to use "avoid patterns" to prevent spidering any URL that matches a wildcarded pattern. This example avoids URLs containing the substrings "java", "python", or "perl".

Download Chilkat Spider ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  The Chilkat Spider component/library is free.
set spider = CreateObject("Chilkat.Spider")

'  The spider object crawls a single web site at a time.  As you'll see
'  in later examples, you can collect outbound links and use them to
'  crawl the web.  For now, we'll simply spider 10 pages of chilkatsoft.com
spider.Initialize "www.chilkatsoft.com"

'  Add the 1st URL:
spider.AddUnspidered "http://www.chilkatsoft.com/"

'  Avoid URLs matching these patterns:
spider.AddAvoidPattern "*java*"
spider.AddAvoidPattern "*python*"
spider.AddAvoidPattern "*perl*"

'  Begin crawling the site by calling CrawlNext repeatedly.

For i = 0 To 10

    success = spider.CrawlNext()
    If (success = 1) Then
        '  Show the URL of the page just spidered.
        outFile.WriteLine(spider.LastUrl)
        '  The HTML is available in the LastHtml property
    Else
        '  Did we get an error or are there no more URLs to crawl?
        If (spider.NumUnspidered = 0) Then
            MsgBox "No more URLs to spider"
        Else
            MsgBox spider.LastErrorText
        End If

    End If

    '  Sleep 1 second before spidering the next URL.
    spider.SleepMs 1000
Next


outFile.Close