Socket/SSL/TLS through SOCKS5 / SOCKS4 Proxy

Demonstrates how to use the Chilkat Socket/SSL/TLS component/library with a SOCKS5 or SOCKS4 proxy server.

Download Chilkat Socket ActiveX

set socket = CreateObject("Chilkat.Socket")

success = socket.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock component"
    WScript.Quit
End If

'  To use a SOCKS4 or SOCKS5 proxy, simply set the following
'  properties prior to calling Connect.  The connection may be SSL/TLS or
'  non-secure - both will work with a SOCKS proxy.
'  The SOCKS hostname may be a domain name or
'  IP address:
socket.SocksHostname = "www.mysocksproxyserver.com"
socket.SocksPort = 1080
socket.SocksUsername = "myProxyLogin"
socket.SocksPassword = "myProxyPassword"
'  Set the SOCKS version to 4 or 5 based on the version
'  of the SOCKS proxy server:
socket.SocksVersion = 5
'  Note: SOCKS4 servers only support usernames without passwords.
'  SOCKS5 servers support full login/password authentication.

'  Connect to port 5555 of 192.168.1.108.
'  hostname may be a domain name or IP address.
hostname = "192.168.1.108"
ssl = 0
maxWaitMillisec = 20000
success = socket.Connect(hostname,5555,ssl,maxWaitMillisec)
If (success <> 1) Then
    MsgBox socket.LastErrorText
    WScript.Quit
End If

'  Set maximum timeouts for reading an writing (in millisec)
socket.MaxReadIdleMs = 10000
socket.MaxSendIdleMs = 10000

'  The server (in this example) is going to send a "Hello World!"
'  message.  Read it:

receivedMsg = socket.ReceiveString()
If (receivedMsg = vbNullString ) Then
    MsgBox socket.LastErrorText
    WScript.Quit
End If

'  Close the connection with the server
'  Wait a max of 20 seconds (20000 millsec)
socket.Close 20000

MsgBox receivedMsg