Debugging with Socket Session Logging

Debugging with socket session logging.

The Chilkat Socket component provides properties for keeping a session log making it possible to see the exact bytes received and sent on a TCP/IP or SSL connection. To enable session logging, set the KeepSessionLog property = 1. The SessionLogEncoding property controls how binary, non-printable bytes are represented in the log. There are two possible settings: Possible values are "esc" and "hex". The default value is "esc".

When set to "hex", the bytes are encoded as a hexidecimalized string. The "esc" encoding is a C-string like encoding, and is more compact than hex if most of the data to be logged is text. Printable us-ascii chars are unmodified. Common "C" control chars are represented as "\r", "\n", "\t", etc. Non-printable and byte values greater than 0x80 are escaped using a backslash and hex encoding: \xHH. Certain printable chars are backslashed: SPACE, double-quote, single-quote, etc.

Download Chilkat Socket ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set socket = CreateObject("Chilkat.Socket")

success = socket.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock component"
    WScript.Quit
End If

'  Enable session logging:
socket.KeepSessionLog = 1
socket.SessionLogEncoding = "esc"

'  To demonstrate session logging, we'll connect to an
'  HTTP server and download the HTTP response header:
ssl = 0
maxWaitMillisec = 20000
success = socket.Connect("www.chilkatsoft.com",80,ssl,maxWaitMillisec)
If (success <> 1) Then
    MsgBox socket.LastErrorText
    WScript.Quit
End If

'  Set maximum timeouts for reading an writing (in millisec)
socket.MaxReadIdleMs = 10000
socket.MaxSendIdleMs = 10000

'  The socket component includes a BuildHttpGetRequest
'  method for convenience. Build a GET and send it to
'  the web server:

httpGet = socket.BuildHttpGetRequest("http://www.chilkatsoft.com/")

'  Send it...
success = socket.SendString(httpGet)
If (success <> 1) Then
    MsgBox socket.LastErrorText
    WScript.Quit
End If

'  Read the response up to the first double CRLF:

httpHeader = socket.ReceiveUntilMatch("\r\n\r\n")
If (httpHeader = vbNullString ) Then
    MsgBox socket.LastErrorText
    WScript.Quit
End If

'  Close the connection with the server
'  Wait a max of 20 seconds (20000 millsec)
socket.Close 20000

'  Display the session log:
outFile.WriteLine(socket.SessionLog)

'  Show the HTTP response header:
outFile.WriteLine(httpHeader)
outFile.Close