Accept Connection on Socket

Demonstrates how to create a TCP/IP socket, listen on a port, accept an incoming connection, and send a "Hello World" message to the client.

Download Chilkat Socket ActiveX

set listenSocket = CreateObject("Chilkat.Socket")

success = listenSocket.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock component"
    WScript.Quit
End If

'  Bind to a port and listen for incoming connections:
'  This example will listen at port 5555 and allows for a backlog
'  of 25 pending connection requests.
success = listenSocket.BindAndListen(5555,25)
If (success <> 1) Then
    MsgBox listenSocket.LastErrorText
    WScript.Quit
End If

'  Get the next incoming connection
'  Wait a maximum of 20 seconds (20000 millisec)

Set connectedSocket = listenSocket.AcceptNextConnection(20000)
If (connectedSocket Is Nothing ) Then
    MsgBox listenSocket.LastErrorText
    WScript.Quit
End If

'  Set maximum timeouts for reading an writing (in millisec)
connectedSocket.MaxReadIdleMs = 10000
connectedSocket.MaxSendIdleMs = 10000

'  Send a "Hello World!" message to the client:
success = connectedSocket.SendString("Hello World!")
If (success <> 1) Then
    MsgBox connectedSocket.LastErrorText

    WScript.Quit
End If

'  Close the connection with the client.
'  Wait a max of 20 seconds (20000 millsec)
connectedSocket.Close 20000

MsgBox "success!"