SMTP SSH Tunneling (Port Forwarding)

Demonstrates how to setup an SSH tunnel for SMTP. This example connects to an SMTP sever via an SSH tunnel and sends an email.

Download Chilkat Email ActiveX

Download Chilkat IMAP ActiveX

'  The mailman object is used for sending (SMTP) and receiving (POP3) email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial.")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Connect to an SSH server and establish the SSH tunnel:

'  The SSH hostname may be a hostname or an
'  IP address, such as "192.168.1.108".
'  The port is typically 22 (the standard port for SSH).
sshHostname = "www.my-ssh-server.com"
sshPort = 22
bSmtp = 1
'  The 1st argument passed to SshTunnel indicates whether
'  a tunnel for SMTP or POP3 is being established.
success = mailman.SshTunnel(bSmtp,sshHostname,sshPort)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

'  Authenticate with the SSH server via a login/password
'  or with a public key.
'  This example demonstrates SSH password authentication.
'  Note: This is not authenticating with the SMTP server, it is
'  for authenticating with the SSH server, which is separate.
success = mailman.SshAuthenticatePw(bSmtp,"sshLogin","sshPassword")
If (success <> 1) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

'  OK, the SSH tunnel is setup.  The mailman may
'  be used exactly the same as usual, except all communications
'  are now sent through the SSH tunnel.

'  Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"

'  Set the SMTP login/password (if required)
mailman.SmtpUsername = "smtpLogin"
mailman.SmtpPassword = "smtpPassword"

'  Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Chilkat Admin","admin@chilkatsoft.com"

'  The call to SendEmail automatically connects to the SMTP
'  server via the SSH tunnel (if not already connected).
'  Because the SSH tunnel has been previously setup,
'  this does not establish a direct connection with the SMTP
'  server.  It directs the SSH server to establish the connection.

'  After SendEmail completes, the connection (i.e. session) remains
'  open so that subsequent SendEmail calls may use the
'  same SSH tunnel.
success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

'  If you're curious, have a look at LastErrorText after
'  a successful send.  You'll see detailed information that
'  confirms the SSH tunneling.
MsgBox mailman.LastErrorText

'  Note: Some SMTP servers do not actually send the email until
'  the connection is closed.  In these cases, it is necessary to
'  call CloseSmtpConnection for the mail to be  sent.
'  Most SMTP servers send the email immediately, and it is
'  not required to close the connection.

MsgBox "Mail Sent!"