Send a Simple Email

Create a simple email and sends it. The SendEmail method establishes a connection (session) with the SMTP server if necessary, and leaves the connection open so that additional sends may proceed using the same session. The SMTP connection (session) may be explicitly closed by calling CloseSmtpSession.

Important: Some SMTP servers do not actually send the email until the connection is closed. In these cases, it is necessary to call CloseSmtpConnection for the mail to be sent. Most SMTP servers send the email immediately, and it is not required to close the connection.

More information about minimizing SMTP connections.

Download Chilkat Email ActiveX

Download 32-bit Chilkat IMAP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"

'  Set the SMTP login/password (if required)
mailman.SmtpUsername = "myUsername"
mailman.SmtpPassword = "myPassword"

'  Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Chilkat Admin","admin@chilkatsoft.com"
'  To add more recipients, call AddTo, AddCC, or AddBcc once per recipient.

'  Call SendEmail to connect to the SMTP server and send.
'  The connection (i.e. session) to the SMTP server remains
'  open so that subsequent SendEmail calls may use the
'  same connection.
success = mailman.SendEmail(email)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

'  Some SMTP servers do not actually send the email until
'  the connection is closed.  In these cases, it is necessary to
'  call CloseSmtpConnection for the mail to be  sent.
'  Most SMTP servers send the email immediately, and it is
'  not required to close the connection.  We'll close it here
'  for the example:
success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    MsgBox "Connection to SMTP server not closed cleanly."
End If

MsgBox "Mail Sent!"
outFile.Close