Send S/MIME Signed Email

Send digitally signed email using the digital certificate of the recipient. To successfully sign, the sender's certificate must be pre-installed with private key. Typically, this is done via a .pfx file, or through Internet Explorer. If your code is going to run within ASP, ASP.NET, or a Windows Service, you will need to follow the instructions here (http://blog.chilkatsoft.com/?p=149) to import your certificate w/ private key such that it is accessible by the calling process.

Download Chilkat Email ActiveX for POP3 / SMTP

Download Chilkat IMAP ActiveX

' The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

' Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

' Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

' Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This email is signed"
email.Body = "This is a digitally signed mail"
email.From = "Chilkat Support <admin@chilkatsoft.com>"
email.AddTo "TagTooga","admin@tagtooga.com"

' In this example, we've already installed the certificate for "admin@chilkatsoft.com"
' (with private key) in the current user's personal certificate store.
' If the email.SendSigned property is set, Chilkat will
' automatically search for and use the first non-expired certificate
' matching the sender's email address.  Chilkat searches
' the Current User's Personal certificate store, as well
' as the Local Machine's Personal certificate store.
' Run certmgr.msc to view the certs in the Current User's
' certificate store.
email.SendSigned = 1

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"
End If