Using a .cer Certificate File for Encrypted Email

Sends an encrypted email using the recipient's digital certificate from a .cer file.

Download Chilkat Email ActiveX

Download Chilkat IMAP ActiveX

'  The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

'  Load the .cer file into a certificate object:
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadFromFile("comodoChilkat.cer")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    WScript.Quit
End If

'  Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Comodo Test","comodo@chilkatsoft.com"

'  Indicate that the email is to be sent encrypted.
email.SendEncrypted = 1

'  Specify the certificate:
email.SetEncryptCert cert

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"
End If