Send S/MIME Encrypted Email

Send encrypted email using the digital certificate of the recipient. To successfully encrypt, the recipient's certificate must be installed or available from a .cer file or elsewhere (such as LDAP, a database, etc.). Only the public key is required to encrypt an email. The private key is not necessary. (The private key is necessary for decryption. Thus, when an encrypted email is sent, only the recipient may decrypt because only the recipient holds the private key.)

Download Chilkat Email ActiveX for POP3 / SMTP

Download Chilkat IMAP ActiveX

'  The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

'  Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "TagTooga","admin@tagtooga.com"

'  In this example, we've already installed the certificate for "admin@tagtooga.com"
'  in the current user's personal certificate store.
'  If the email.SendEncrypted property is set, Chilkat will
'  automatically search for and use the first non-expired certificate
'  matching the recipient's email address.  Chilkat searches
'  the Current User's Personal certificate store, as well
'  as the Local Machine's Personal certificate store.
'  Run certmgr.msc to view the certs in the Current User's
'  certificate store.
email.SendEncrypted = 1

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"
End If